vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2018
 
zurück
Rubrik: Datenbanken · ADO   |   VB-Versionen: VB609.02.10
Tabellenverknüpfung erstellen (ADO)

Eine Funktion, mit der sich eine Datenbanktabelle aus einer externen Quelle dauerhaft in die aktiv geöffnete Datenbank einfügen lässt.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  12.361 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10kein Beispielprojekt 

Heute stellen wir Ihnen eine Funktion vor, mit der sich eine Datenbanktabelle aus einer externen Quelle (bspw. Access-Datenbank) dauerhaft in die aktiv geöffnete Datenbank einfügen lässt, so dass man anschließend auf die Daten der externen Tabelle so zugreifen kann, als wäre die Tabelle Bestandteil der eigenen Datenbank.

Public Function dbCreateLink(ByRef oConn As ADODB.Connection, _
  ByVal sExternFile As String, _
  ByVal sExternTable As String, _
  Optional ByVal sLinkTableName As String = "") As Boolean
 
  Dim oCat As ADOX.Catalog
  Dim oTable As ADOX.Table
 
  ' Fehlerbehandlung aktivieren
  On Error Goto ErrHandler
 
  ' Katalog-Objekt der aktiven Connection erstellen
  Set oCat = New ADOX.Catalog
  oCat.ActiveConnection = oConn
 
  ' neue Tabelle anlegen
  Set oTable = New ADOX.Table
  With oTable
    Set .ParentCatalog = oCat
 
    ' Name der Tabelle
    If Len(sLinkTableName) = 0 Then sLinkTableName = sExternTable
    .Name = sLinkTableName
 
    ' Eigenschaften der neuen Tabelle festlegen
    .Properties("Jet OLEDB:Create Link") = True
    .Properties("Jet OLEDB:Link Datasource") = sExternFile
    .Properties("Jet OLEDB:Remote Table Name") = sExternTable
  End With
  oCat.Tables.Append oTable
 
  dbCreateLink = True
 
  Set oCat = Nothing
  On Error Goto 0
  Exit Function
 
ErrHandler:
  MsgBox "Tabellenverknüpfung konnte nicht erstellt werden!" & vbCrLf & _
    "Fehler " & CStr(Err.Number) & vbCrLf & Err.Description
  dbCreateLink = False
  Set oCat = Nothing
End Function

Für das Hinzufügen einer neuen Tabelle zu einer bestehenden Connection benötigen wir einen Verweis auf die Microsoft ADO Ext 2.x for DDL and Security Library.

Aufrufbeispiel:
Es soll aus der Datenbank "d:\Test.mdb" die Tabelle "Kunden" in die aktuelle Datenbank als "Verweis" eingefügt werden.

' Eigene Datenbank öffnen
Dim oConn As ADODB.Connection
Set oConn = New ADODB.Connection
With oConn
  .Provider = "Microsoft.Jet.OLEDB.4.0"
  .Properties("Data Source") = App.Path & "\MyMDB.mdb"
  .Properties("Persist Security Info") = False
  .Open 
End With
 
' jetzt die Tabellenverknüpfung erstellen und hinzufügen
If dbCreateLink(oConn, "d:\Test.mdb", "Kunden", "KundenExt") Then
  ' ...
End If

Dieser Tipp wurde bereits 12.361 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Aktuelle Diskussion anzeigen (3 Beiträge)

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2018 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel