Anwendugsdatenverzeichnis des Users ermitteln Mit diesen Funktionen ermitteln Sie das Anwendungsdatenverzeichnis des aktuellen Users bzw. das gemeinsame Anwendungsdatenverzeichnis aller User
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  10.846
https://www.tools4vb.com	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 2 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 4.5 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Spätestens seit Windows Vista sollte man Anwendungsdaten nicht mehr im Programmverzeichnis speichern, da der Benutzer i.a.R. nur Leserechte auf den Programmordner hat.

Datendateien, die vom Programm erzeugt oder verändert werden, gehören in das Anwendungsdatenverzeichnis des aktuell angemeldeten Benutzers bzw. in das gemeinsame Anwendungsdatenverzeichnis, wenn mehrere Benutzer auf die Daten zugreifen müssen.

Je nach Betriebssystem lautet das Anwendungsdatenverzeichnis jedoch anders, so dass man hier nicht einfach einen festen Ordnernamen in der Anwendung verwenden kann.

Mit nachfolgendem Code ermitteln Sie sowohl das Anwendungsdatenverzeichnis des aktuellen Benutzers, als auch das gemeinsame Anwendungsdatenverzeichnis aller Benutzer.

Option Explicit
 
' benötigte API-Deklarationen
Private Const TOKEN_QUERY = (&H8)
Private Declare Function GetAllUsersProfileDirectory Lib "userenv.dll" _
  Alias "GetAllUsersProfileDirectoryA" ( _
  ByVal lpProfileDir As String, _
  lpcchSize As Long) As Boolean
 
Private Declare Function GetUserProfileDirectory Lib "userenv.dll" _
  Alias "GetUserProfileDirectoryA" ( _
  ByVal hToken As Long, ByVal lpProfileDir As String, _
  lpcchSize As Long) As Boolean
 
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
 
Private Declare Function OpenProcessToken Lib "advapi32" ( _
  ByVal ProcessHandle As Long, _
  ByVal DesiredAccess As Long, _
  TokenHandle As Long) As Long

' Ermittelt das gemeinsame Anwendungsdatenverzeichnis
Public Function CommonAppData() As String
  Dim sBuffer As String
 
  sBuffer = String$(255, 0)
  GetAllUsersProfileDirectory sBuffer, 255
 
  CommonAppData = TrimNull(sBuffer)
End Function

' Ermittelt das Anwendungsverzeichnis des aktuell angemeldeten Benutzers
Public Function UserAppData() As String
  Dim sBuffer As String
  Dim hToken As Long
 
  sBuffer = String$(255, 0)
  OpenProcessToken GetCurrentProcess, TOKEN_QUERY, hToken
  GetUserProfileDirectory hToken, sBuffer, 255
 
  UserAppData = TrimNull(sBuffer)
End Function

' Hilfsfunktion
Private Function TrimNull(ByVal sBuffer As String) As String
  Dim nPos As Long
  nPos = InStr(sBuffer, Chr$(0))
  If nPos > 0 Then
    TrimNull = Left$(sBuffer, nPos - 1)
  Else
    TrimNull = sBuffer
  End If
End Function