vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Erstellen von dynamischen Kontextmen?s - wann immer Sie sie brauchen!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Dateisystem · Ordner & Verzeichnisse   |   VB-Versionen: VB4, VB5, VB610.07.01
Laufwerks-Pfad nach UNC-Pfad und umgekehrt

Zwei hilfreiche Routinen für die Umwandelung von UNC- nach Laufwerks-Pfaden und umgekehrt.

Autor:   Jost SchwiderBewertung:     [ Jetzt bewerten ]Views:  28.628 
www.vb-tec.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Sogenannte "UNC-Pfade" kommen immer dann ins Spiel, wenn Ressourcen im Netz (auf einem "File-Server") benutzt werden sollen. Einem öfter benötigtem Server-Verzeichnis wird der Einfachheit halber oft ein Laufwerk zugeordnet (z.B. als "Arbeitsgruppen-Laufwerk", im Beispiel W. Dann kann z.B. statt mit der unübersichtlichen UNC-Notation \\FileSvr2\WebAG\Infos\ einfach über ein "virtuelles" Laufwerk zugegriffen werden: W:\Infos\

Nachfolgend werden zwei Funktionen vorgestellt, welche gerade die Umwandlung zwischen UNC- und Laufwerks-Pfad erlauben.

Laufwerks- nach UNC-Pfad
Im Deklarationsteil eines Moduls wird folgende API-Funktion benötigt:

' zunächst die benötigte API-Deklaratione
Private Declare Function WNetGetConnectionA Lib "mpr.dll" ( _
  ByVal lpszLocalName As String, _
  ByVal lpszRemoteName As String, _
  cbRemoteName As Long) As Long

Die folgende Funktion nutzt die o.g. API-Routine, wobei der ggf. angehängte Pfad besonders behandelt wird. Wird ein unbekanntes Laufwerk angegeben, so wird eine entsprechende Fehlermeldung zurückgegeben (kann mit IgnoreErrors = True unterdrückt werden).

Public Function UNCPath(ByVal Path As String, _
  Optional IgnoreErrors As Boolean = False) As String
  Dim UNC As String * 512
 
  If Len(Path) = 1 Then Path = Path & ":"
  If Right$(Path, 1) <> "\" Then Path = Path & "\"
  If WNetGetConnectionA(Left$(Path, 2), UNC, Len(UNC)) Then
 
    ' API-Routine gibt Fehler zurück:
    If IgnoreErrors Then
      UNCPath = Path
    Else
      Err.Raise 5 ' Invalid procedure call or argument
    End If
 
  Else
 
    ' Ergebnis zurückgeben:
    UNCPath = Left$(UNC, InStr(UNC, vbNullChar) - 1) _
            & Mid$(Path, 3)
 
  End If
End Function

UNC- nach Laufwerks-Pfad
Die Umkehrfunktion benutzt die LogicalDrives-Funktion, um alle Laufwerke nach und nach in UNC umzuwandeln. Bei Übereinstimmung mit dem gesuchten UNC wird das entsprechende Ergebnis zurückgegeben. Existiert kein Laufwerk für den angegebenen UNC-Pfad, so wird eine entsprechende Fehlermeldung zurückgegeben (kann mit IgnoreErrors = True unterdrückt werden).

' zunächst die benötigten API-Deklarationen
Private Declare Function GetLogicalDriveStringsA Lib "kernel32" ( _
  ByVal nBufferLength As Long, _
  ByVal lpBuffer As String) As Long
 
Public Function LogicalDrives() As Collection
  Dim s As String * 128
  Dim i As Long
 
  ' API aufrufen:
  GetLogicalDriveStringsA Len(s), s
  i = InStr(s, vbNullChar & vbNullChar) ' Länge
 
  ' Collection füllen:
  Set LogicalDrives = New Collection
  For i = 1 To i Step 4
    LogicalDrives.Add Mid$(s, i, 2)
  Next i
End Function
 
' Ermittelt das Laufwerk für einen UNC-Pfad
Public Function DrivePath(ByVal Path As String, _
  Optional IgnoreErrors As Boolean = False) As String
  Dim Drive As Variant
  Dim UNC As String
 
  ' Alle Laufwerke durchsuchen:
  If Right$(Path, 1) <> "\" Then Path = Path & "\"
  For Each Drive In LogicalDrives <findfile.htm>()
    UNC = UNCPath(Drive, True)
    If InStr(1, Path, UNC, vbTextCompare) = 1 Then Exit For
  Next Drive
 
  If IsEmpty(Drive) Then
 
    ' Kein Laufwerk für UNC gefunden:
    If IgnoreErrors Then
      DrivePath = Path
    Else
      Err.Raise 5  'Invalid procedure call or argument
    End If
 
  Else
 
    ' Ergebnis zurückgeben:
    DrivePath = Drive & Mid$(Path, Len(UNC))
 
  End If
End Function

Anmerkung:
Dieser Tipp eignet sich gut als Ergänzung zu unserem Tipp:
 Aufruf von Netzlaufwerk aus verhindern
 

Dieser Tipp wurde bereits 28.628 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel