vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevDataGrid - Gönnen Sie Ihrem SQL-Kommando diesen krönenden Abschluß!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: HTML/Internet/Netzwerk · Internet / Browser / IE   |   VB-Versionen: VB4, VB5, VB603.11.00
Standardbrowser ermitteln

Mit nachfolgender Funktion können Sie den im System festgelegten Standard-Browser ermitteln. Die Funktion gibt hierbei den vollständigen Dateinamen ...

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  24.741 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Mit nachfolgender Funktion können Sie den im System festgelegten Standard-Browser ermitteln. Die Funktion gibt hierbei den vollständigen Dateinamen (inkl. Pfad) zurück und zusätzlich noch den Namen (die Bezeichnung), sollte es sich um den MSIE, Netscape oder Opera-Browser handeln.

' Hier die benötigten API-Deklarationen
Declare Function FindExecutable Lib "shell32.dll" _
  Alias "FindExecutableA" ( _
  ByVal lpFile As String, _
  ByVal lpDirectory As String, _
  ByVal lpResult As String) As Long
 
' Diese Funktion ermittelt den im System festgelegten
' Standard-Browser und gibt den Pfad inkl. Dateinamen
' zurück.
' 
' Zusätzlich wird in der Variable sName noch der Name
' des Browsers zurückgegegen
' 
' Ist kein Standard-Browser eingerichtet, so wird ein
' Leerstring zurückgegeben
Public Function StandardBrowser(sName As String) As String
 
  Dim sExe As String
  Dim tmpFile As String
  Dim F As Integer
 
  tmpFile = App.Path + IIf(Right$(App.Path, 1) <> "\", _
    "\", "") + "test~12345.html"
  F = FreeFile
  Close #F: Open tmpFile For Output As #F
  Close #F
  sExe = AnwendungFuerDatei(tmpFile)
  Kill tmpFile
 
  If sExe <> "" Then
    If InStr(LCase$(sExe), "iexplore") > 0 Then
      sName = "Microsoft Internet Explorer"
    ElseIf InStr(LCase$(sExe), "netscape") > 0 Then
      sName = "Netscape Communicator"
    ElseIf InStr(LCase$(sExe), "opera") > 0 Then
      sName = "Opera-Browser"
    Else
      sName = ""
    End If
  End If
 
  StandardBrowser = sExe
End Function
 
' Diese Funktion ermittelt die Standard-Anwendung
' in Verbindung mit einem bestimmten Dateityp
' 
' Die Funktion gibt als Ergebnis den Dateinamen mit
' vollständigen Pfad zurück
' 
' Kann keine assoziierte Anwendung ermittelt werden
' wird ein Leerstring zurückgegeben
 
' Diese Funktion stammt aus einem vorigen Tipp
Public Function AnwendungFuerDatei(ByVal Datei As String) _
  As String
 
  ' Datei: Pfad+Dateinamen einer existierenden Datei
 
  Dim Pfad As String
 
  Pfad = Space$(256)
  FindExecutable Datei, vbNullString, Pfad
  If Pfad <> "" Then
    Pfad = Left$(Pfad, InStr(Pfad, vbNullChar) - 1)
  End If
  If UCase$(Pfad) = UCase$(Datei) Then Pfad = ""
 
  AnwendungFuerDatei = Pfad
End Function

Dieser Tipp wurde bereits 24.741 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel