vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevAniGif - als kostenlose Vollversion auf unserer vb@rchiv CD Vol.5  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Drucker   |   VB-Versionen: VB4, VB5, VB602.11.01
Papiergröße und nichtbedruckbare Ränder ermitteln

Dieses Beispiel zeigt, wie sich die Papiergröße, sowie die nichtbedruckbaren Ränder eines beliebigen Druckers ermitteln lassen.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  20.384 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Dieser Tipp zeigt, wie sich die nichtbedruckbaren Ränder eines beliebigen im System installierten Druckers ermitteln lassen.

' zunächst die benötigten API-Deklarationen
Private Declare Function GetDeviceCaps Lib "GDI32" ( _
  ByVal hDC As Long, _
  ByVal nIndex As Long) As Long

Die nachfolgende Prozedur ermittelt für das im ersten Parameter angegeben Druckerobjekt folgende Rand- und Papier-Einstellungen:

  • pLeft: nichbedruckbarere Rand "links"
  • pTop: nichtbedruckbarer Rand "oben"
  • pWidth: Papierbreite insgesamt
  • pHeight: Papiergröße insgesamt
  • pRight: nichtbedruckbarer Rand "rechts"
  • pBottom: nichtbedruckbarer Rand "unten"
In welcher Maßeinheit die Ergebnisse zurückgeliefert werden sollen legen Sie im letzten Parameter fest:
  • vbTwips (1)
  • vbPoints (2)
  • vbPixels (3)
  • vbInches (5)
  • vbMillimeters (6)
  • vbCentimeters (7)

' Ermitteln der nichtbedruckbaren Ränder
Public Sub GetPhysicalPageSize(Printer As Object, _
  pLeft As Long, pTop As Long, _
  Optional pWidth As Long, Optional pHeight As Long, _
  Optional pRight As Long, Optional pBottom As Long, _
  Optional ByVal ScaleMode As Integer = vbMillimeters)
 
  Const PHYSICALWIDTH = 110
  Const PHYSICALHEIGHT = 111
  Const PHYSICALOFFSETX = 112
  Const PHYSICALOFFSETY = 113
 
  With Printer
    ' Papiergröße
    pWidth = .ScaleX(GetDeviceCaps(.hDC, _
      PHYSICALWIDTH), vbPixels, ScaleMode)
    pHeight = .ScaleY(GetDeviceCaps(.hDC, _
      PHYSICALHEIGHT), vbPixels, ScaleMode)
 
    ' nicht bedruckbare Ränder: Links und Oben
    pLeft = .ScaleX(GetDeviceCaps(.hDC, _
      PHYSICALOFFSETX), vbPixels, ScaleMode)
    pTop = .ScaleY(GetDeviceCaps(.hDC, _
      PHYSICALOFFSETY), vbPixels, ScaleMode)
 
    ' nicht bedruckbare Ränder: Rechts und unten
    pRight = pWidth - pLeft - _
      .ScaleX(.ScaleWidth, .ScaleMode, ScaleMode)
    pBottom = pHeight - pTop - _
      .ScaleY(.ScaleHeight, .ScaleMode, ScaleMode)
  End With
End Sub

Beispiel
Das nachfolgende Beispiel ermittelt die nichtbedruckbaren Ränder, sowie die eingestellte Papiergröße und zeigt die Werte in der Maßeinheit "Millimeter" in einer MsgBox an.

Dim pLeft As Long
Dim pTop As Long
Dim pRight As Long
Dim pBottom As Long
Dim pWidth As Long
Dim pHeight As Long
Dim sMsg As String
 
' Einstellungen des Standard-Druckers
GetPhysicalPageSize Printer, pLeft, pTop, _
  pWidth, pHeight, pRight, pBottom, vbMillimeters
 
sMsg = "Papiergröße: " & CStr(pWidth) & _
  " x " & CStr(pHeight) & "mm" & vbCrLf & _
  "Linker Rand: " & CStr(pLeft) & "mm" & vbCrLf & _
  "Rechter Rand: " & CStr(pRight) & "mm" & vbCrLf & _
  "Oberer Rand: " & CStr(pTop) & "mm" & vbCrLf & _
  "Unterer Rand: " & CStr(pBottom) & "mm"
 
MsgBox sMsg

Dieser Tipp wurde bereits 20.384 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel