vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2021
 
zurück
Rubrik: Controls · ListBox   |   VB-Versionen: VB4, VB5, VB615.12.01
Listbox-Markierungen per API in ein Array kopieren

Mit Hilfe der SendMessage-Funktion lassen sich die Indizes aller markierten ListBox-Einträge schnell in ein Array kopieren.

Autor:   Bodo ErmshausBewertung:     [ Jetzt bewerten ]Views:  13.454 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Das Bearbeiten einer Listbox mit üblichen VB-Mitteln ist bei größerer Datenmenge oft eine zeitraubende Angelegenheit. Das nachfolgende Beispiel zeigt, wie eine Auswahl aus einer Listbox (Multiselect = 2) mittels der API-Funktion SendMessage zuerst in ein Array kopiert wird und dann z.B. in eine zweite Listbox übertragen wird.

Der Umweg über die For-Next-Schleife, in der jeder Eintrag der Listbox nach seiner Markierung abgefragt wird, entfällt somit.

Erstellen Sie ein neues Projekt, fügen Sie der Form zwei ListBoxen (List1 und List2), sowie einen CommandButton (cmdCopy) hinzu. Setzen Sie die MultiSelect-Eigenschaft der ersten ListBox (List1) auf den Wert 2 - Erweitert. Zunächst wird List1 mit beliebigen Werten gefüllt. Beim Klicken auf den CommandButton werden alle aktuell selektierten Einträge ermittelt und in die zweite ListBox kopiert.

' zunächst die benötigten API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Any) As Long
 
Private Const LB_GETSELCOUNT = &H190
Private Const LB_GETSELITEMS = &H191
Private Sub Form_Load()
  ' zunächst ListBox füllen
  Dim i As Integer
 
  For i = 1 To 100
    List1.AddItem "Eintrag " & CStr(i)
  Next i
End Sub
Private Sub cmdCopy_Click()
  ' alle selektierten Einträge der ListBox per API
  ' in ein Array kopieren
  Dim lCnt As Long
  Dim lResult As Long
  Dim lArr() As Long
  Dim i As Long
 
  ' Anzahl der ausgewälten Einträge bestimmen
  lCnt = SendMessage(List1.hwnd, LB_GETSELCOUNT, 0, 0)
 
  ' Arraygröße festlegen
  ReDim lArr(lCnt)
 
  ' hier wird das Array lArr() mit den Indizes von
  ' List1 gefüllt
  lResult = SendMessage(List1.hwnd, LB_GETSELITEMS, _
    CLng(UBound(lArr)), lArr(0))
 
  ' Übertragen der markierten Einträge anhand der
  ' Indizes im lArr()
  List2.Clear
  For i = 0 To UBound(lArr) - 1
    List2.AddItem List1.List(lArr(i))
  Next
End Sub

Dieser Tipp wurde bereits 13.454 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2021 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel