vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
SEPA-Dateien erstellen inkl. IBAN-, BLZ-/Kontonummernprüfung  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Oberfläche · Fenster   |   VB-Versionen: VB4, VB5, VB611.02.02
Fenster IMMER sichtbar anzeigen

Nachfolgender Tipp zeigt, wie eine Form immer sichtbar angezeigt wird und nicht - auch nicht vom Desktop - verdeckt werden kann.

Autor:   TekoWBewertung:     [ Jetzt bewerten ]Views:  35.855 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Wie lässt sich eine Form immer im Vordergrund anzeigen? D.h. das Fenster soll nicht von anderen Anwendungsfenstern verdeckt werden können.

Hierzu haben wir Ihnen vor längerer Zeit schon einmal eine entsprechende Lösung aufgezeigt - und zwar mittels der API-Funktion SetWindowPos.

Das ganze funktioniert auch sehr gut - nur: Das Fenster lässt sich durch einen Klick auf "Desktop anzeigen" vom Desktop verdecken. Was aber, wenn das Fenster immer im Vordergrund angezeigt werden soll?

Lösung:
Man setze die BorderStyle-Eigenschaft der Form auf 3 - Dialog. Der Nachteil ist: Standardmässig werden jetzt keine Minimieren- und Maximieren-Buttons mehr angezeigt. Doch auch hierfür gibt es eine (API-)Lösung

Fügen Sie den gesamten nachfolgende Code in ein Modul ein.

Option Explicit
 
' alle benötigten API-Deklarationen
Private Declare Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal hWndInsertAfter As Long, _
  ByVal x As Long, _
  ByVal y As Long, _
  ByVal cx As Long, _
  ByVal cy As Long, _
  ByVal wFlags As Long) As Long
 
Private Declare Function GetWindowLong Lib "user32" _
  Alias "GetWindowLongA" ( _
  ByVal hwnd As Long, _
  ByVal nIndex As Long) As Long
 
Private Declare Function SetWindowLong Lib "user32" _
  Alias "SetWindowLongA" ( _
  ByVal hwnd As Long, _
  ByVal nIndex As Long, _
  ByVal dwNewLong As Long) As Long
 
Private Const SWP_FRAMECHANGED = &H20
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOZORDER = &H4
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_REFRESH = SWP_NOZORDER Or _
  SWP_NOSIZE Or SWP_NOMOVE Or SWP_NOACTIVATE Or _
  SWP_FRAMECHANGED
 
Private Const GWL_STYLE = (-16)
 
Private Const WS_MAXIMIZEBOX = &H10000
Private Const WS_MINIMIZEBOX = &H20000
 
Private Const HWND_TOPMOST = -1
' Minimieren/Maximieren Button einer Form anzeigen
Public Sub MinMaxButton(Form As Form)
  Dim Style As Long
 
  With Form
    Style = GetWindowLong(.hwnd, GWL_STYLE)
    Style = Style Or WS_MINIMIZEBOX Or WS_MAXIMIZEBOX
    SetWindowLong .hwnd, GWL_STYLE, Style
    SetWindowPos .hwnd, 0, 0, 0, 0, 0, SWP_REFRESH
  End With
End Sub
' Fenster immer im Vordergrund
Public Sub TopWindow(hwnd As Long)
  SetWindowPos hwnd, HWND_TOPMOST, 0, 0, 0, 0, _
    SWP_NOSIZE + SWP_NOMOVE
End Sub

Um nun ein Fenster immer im Vordergrund anzuzeigen, welches nicht von anderen Anwendungen - auch nicht vom Windows-Desktop - verdeckt werden kann, fügen Sie folgenden Code in das Form_Load Event der Form ein:

Private Sub Form_Load()
  ' Minimieren/Maximieren Buttons zur
  ' Laufzeit anzeigen
  MinMaxButton Me
 
  ' Fenster immer im Vordergrund anzeigen
  TopWindow Me.hwnd
End Sub

Einzig das Aktivieren des Bildschirmschoners kann das Fenster nun verdecken. Und wenn Sie diesen Zustand auch noch verhindern möchten, müssen Sie einfach noch einen Timer auf die Form setzen, die Interval-Eigenschaft entsprechendfestlegen und folgenden Code einfügen:

Private Sub Timer1_Timer()
  Call TopWindow(Me.hwnd)
End Sub

Dieser Tipp wurde bereits 35.855 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel