vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevAniGif - als kostenlose Vollversion auf unserer vb@rchiv CD Vol.5  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Variablen/Strings · Sonstiges   |   VB-Versionen: VB4, VB5, VB616.09.02
Stichwortverzeichnis erstellen

Aufbau eines Stichwortverzeichnisses aus einem MultiLine-Text.

Autor:   Michael BeckerBewertung:     [ Jetzt bewerten ]Views:  14.228 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

In manchen Programmen ist es sinnvoll wenn man ein Stichwort-Verzeichnis anbietet. Dieses Stichwortverzeichnis kann in grossen Datenbankfeldern oder auch in grossen Textfeldern dann sehr hilfreich sein, wenn einzelne Wörter unter verschiedenen Rubriken vorkommen.

Hierzu hab ich mir mal Gedanken gemacht, die ich gerne zur Verfügung stelle.

Für dieses Beispiel benötigt man folgende Komponenten:

  • 1 x Form1
  • 1 x Modul1
  • 1 x Textbox (Multiline=True, Scrollbars = Vertikal)
  • 1 x List1(Sorted = True, Visible = False)
  • 1 x Combo1(Sorted = True, Style = 2 - DropDownliste)
  • 1 x Command1

Die Textbox, Listbox, Combobox und den Command-Button einfach auf die Oberfläche ziehen.

Nachfolgenden Code bitte in das Modul einfügen:

Public Sub filter(frm As Form, WORTLAENGE As Integer)
  ' 
  '   Die WORTLAENGE bestimmt die Anzahl der Zeichen,
  '   die für das bilden eines Inhaltsverzeichnis
  '   sinnvoll erscheinen
  ' 
  '   (Es wäre nicht sinnvoll wenn Wörter wie (in,den,der,...)
  '   ein Inhaltsverzeichnis bilden !!!!
  Dim sFilter As String
  Dim sDublette As String
  Dim zaehler As Integer
  Dim x As Integer
  Dim pos As Long
  Dim sTemp As String
  Dim sCheck As String
 
  ' Erst mal das Combo1-Control unsichtbar machen
  ' (wegen Geschwindigkeit !!!)
 
  frm.Combo1.Visible = False
 
  ' Jetzt mal alle Sonderzeichen außer Buchstaben
  ' und Zahlen rausschmeissen !!!
 
  sCheck = Chr$(34) + ":.-(),;%$§'/\?=+*}][{<>#"
 
  sFilter = frm.Text1.Text
  For x = 1 To Len(sCheck)
    sFilter = Replace(sFilter, Mid$(sCheck, x, 1), "")
  Next x
  sFilter = Replace(sFilter, " ", Chr(13) & Chr(10))
 
  ' Jetzt wird der Inhalt der Textbox (=sFilter) auf
  ' harte Returns geprüft und in einzelne Wörter zerlegt,
  ' die in List1 eingetragen werden.
 
  For x = 1 To Len(sFilter)
    pos = InStr(sFilter, Chr$(13))
    If pos > 0 Then
      sTemp = Mid$(sFilter, 1, pos - 1)
      frm.List1.AddItem sTemp
      sFilter = Mid(sFilter, pos + 2, Len(sFilter))
    End If
  Next x
 
  ' Die nachfolgende Schleife prueft das Listfeld (Sorted=true)
  ' auf Dubletten und auf angegebene Wortlänge um dieses in die
  ' InhaltsVerzeichnis-Combo-Box zu schreiben
 
  With frm.List1
    For x = 0 To .ListCount - 1
      .ListIndex = x
      If sDublette <> .Text Then
        If Len(Trim(.Text)) >= WORTLAENGE Then
          frm.Combo1.AddItem .Text
          sDublette = .Text
        End If
      End If
    Next x
  End With
 
  ' Stichwortverzeichnis sichtbar machen
  frm.Combo1.Visible = True
End Sub

Beim Klicken auf die Schaltfläche soll das Stichwortverzeichnis erstellt werden:

Private Sub Command1_Click()
  ' Wörter ab 6 Buchstaben berücksichtigen
  filter Me, 6 
End Sub

Testen...
Starten Sie das Programm und fügen eine größere Menge Text aus der Zwischenablage in das MultiLine-Textfeld ein. Anschließend klicken Sie auf die Schaltfläche (Command1) und öffnen dann einmal die ComboBox.

Jetzt könnte z.B. durch Auswahl eines Eintrags aus der ComboBox eine SQL-Suche starten, mit der das angewählte Wort in der Datenbank gesucht wird...

Private Sub Combo1_Click()
  If Combo1.ListIndex < 0 Then Exit Sub
 
  Dim Rs As New ADODB.Recordset
  Dim SQL As String
 
  SQL = "SELECT * FROM tblkunden WHERE " & _
    "Notiz LIKE '%" & Combo1.Text & "%' ORDER BY Nachname"
 
  Rs.Open SQL, AdOpenForwardOnly, AdLockReadOnly
  ...