vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Erstellen von dynamischen Kontextmen?s - wann immer Sie sie brauchen!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Dateisystem · Ordner & Verzeichnisse   |   VB-Versionen: VB4, VB5, VB630.06.03
Relativen Pfad ermitteln

Mit der shlwapi.dll ein Leichtes: Das Ermitteln eines relativen Pfades aus zwei absoluten Pfadangaben.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  20.167 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Sollten Sie Webmaster einer eigenen Internetseite sein, wissen Sie sicherlich, dass man z.B. für Bildverweise keine absolute Pfadangabe verwendet, sondern einen relativen Pfad ausgehend vom aktuellen Verzeichnis.

Beispiel:
Ihre Webseite befindet sich im Ordner \homepage\home. Für die Bilder verwenden Sie ein separates Unterverzeichnis homepage\images. In der Webseite selbst geben Sie dann den relativen Pfad in Form von ..\images\bild.gif an, und nicht etwa \homepage\images\bild.gif.

Um nun schnell aus einer absoluten Pfadangaben den Pfad relativ zu einem bestimmten "Stammverzeichnis" zu ermitteln, empfiehlt es sich auf die PathRelativePathTo-Funktion aus der shlwapi.dll zurückzugreifen, die mit dem Internet Explorer ab Version 4 installiert wurde.

' Deklaration der Funktion
Private Declare Function PathRelativePathTo Lib "shlwapi.dll" _
  Alias "PathRelativePathToA" ( _
  ByVal pszPath As String, _
  ByVal pszFrom As String, _
  ByVal dwAttrFrom As Long, _
  ByVal pszTo As String, _
  ByVal dwAttrTo As Long) As Long
 
' Konstanten
Private Const MAX_PATH = 260
Private Const FILE_ATTRIBUTE_DIRECTORY = &H10
Private Const FILE_ATTRIBUTE_NORMAL = &H80

Aufruf der Funktion:

' Ausgangsverzeichnis
Dim sFolder As String
sFolder = "c:\homepage\home"
 
' absolute Pfadangabe zur Bilddatei
Dim sImgFile As String
sImgFile = "c:\homepage\images\bild.gif"
 
' relativen Pfad ermitteln
Dim sPath As String
sPath = Space$(MAX_PATH)
PathRelativePathTo sPath, sFolder, FILE_ATTRIBUTE_DIRECTORY, _
  sImgFile, FILE_ATTRIBUTE_NORMAL
sPath = Left$(sPath, InStr(sPath, Chr$(0)) - 1)

Als Ergebnis (sPath) wird jetzt ..\images\bild.gif zurückgegeben.

Wenn Sie sich obigen Code einmal genau anschauen, stellen Sie fest, dass einmal FILE_ATTRIBUTE_DIRECTORY und einmal FILE_ATTRIBUTE_NORMAL verwendet wurde. Und zwar deshalb, weil "sFolder" ein Verzeichnis ist und "sImageFile" eine Datei.

Erstellen wir uns also eine universelle Funktion, der wir sowohl Verzeichnisse, als auch Dateien als Parameter übergeben können und als Rückgabewert dann immer den jeweiligen relativen Pfad zurückerhalten.

' relative Pfadangabe ermitteln
Public Function GetRelativePath(ByVal sFolder As String, _
  ByVal sDirOrPath As String, _
  Optional ByVal bIsFile As Boolean = True) As String
 
  Dim sPath As String
 
  sPath = Space$(MAX_PATH)
  If PathRelativePathTo(sPath, sFolder, FILE_ATTRIBUTE_DIRECTORY, _
    sDirOrPath, _
    IIf(bIsFile, FILE_ATTRIBUTE_NORMAL, FILE_ATTRIBUTE_DIRECTORY)) <> 0 Then
 
    sPath = Left$(sPath, InStr(sPath, Chr$(0)) - 1)
  Else
    sPath = ""
  End If
 
  GetRelativePath = sPath
End Function

Beispiele für den Aufruf:

sPath = GetRelativePath("c:\homepage\home", _
  "c:\homepages\images\bild.gif")
sPath = GetRelativePath("c:\homepage\home", _
  "c:\homepages\images")

Dieser Tipp wurde bereits 20.167 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel