vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Dateisystem · Ordner & Verzeichnisse   |   VB-Versionen: VB620.08.03
Pfade im Griff

Zwei kleine Funktionen, die einem das Leben mit Pfaden leichter machen :-)

Autor:   Gero BonowBewertung:     [ Jetzt bewerten ]Views:  11.491 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10kein Beispielprojekt 

Heute möchten wir Ihnen zwei kleine Funktionen vorstellen, die einem das Leben mit Pfadangaben in Strings leichter machen.

Public Function GetStr(ByVal Text As String, _
  ByVal Separator As String, _
  ByVal Index As Long, _
  Optional ByVal SelectAllFromIndexToEnd As Boolean = False, _
  Optional ByVal SelectAllFromStartToIndex As Boolean = False, _
  Optional ByVal OnErrorReturnString As String = "Error in GetStr") _
  As String
 
  ' Gibt einen Teilstring aus einer Zeichenfolge zurück,
  ' der sich zwischen Trennzeichen befindet.
  ' 
  ' Beispiel:
  ' 
  '   Text="C:\Windows\System\Rundll32.dll"
  '   Index=2
  '   Separator="\"
  ' 
  '   Der Aufruf würde folgendes zurückgeben:
  ' 
  '   Optionen:                       Ausgabe von GetStr:
  '   ----------------------------------------------------------------
  '   Alle Optional=False             "Windows"
  '   SelectAllFromStartToIndex=True  "C:\Windows"
  '   SelectAllFromIndexToEnd=True    "Windows\System\Rundell32.dll"
  '   Alle Optional=True              "C:\Windows\System\Rundll32.dll"
  ' 
  ' Recht praktisch, wenn man z.B. Pfad und Dateiname
  ' voneinander Trennen will :-)
  ' 
  ' Was passiert, wenn:
  ' 
  ' Syntaktischer Fehler:               Ausgabe von GetStr:
  ' ------------------------------------------------------------------
  ' Separator=""                        Text
  ' Text=""                             ""
  ' Index <1                            Text
  ' Index > als IndexCount im Text      ""
  ' Separator länger/gleich lang Text   ""
  ' Separator nicht gefunden            Text
 
  Dim i As Long
  Dim Stellen As Long
  Dim Cache() As String
  Dim ZW As String
 
  On Error GoTo ExitByError
  If SelectAllFromStartToIndex And SelectAllFromIndexToEnd Then
    GetStr = Text
  End If
 
  If Len(Text) = 0 Or Len(Text) <= Len(Separator) Then
    GetStr = ""
    Exit Function
  End If
 
  If Len(Separator) = 0 Or Index < 1 Or _
    InStr(1, Text, Separator) = 0 Then
 
    GetStr = Text
    Exit Function
  End If
 
  Cache = Split(Text, Separator)
  Stellen = UBound(Cache())
  If (Stellen + 1) < Index Then
    GetStr = ""
    Exit Function
  End If
 
  If SelectAllFromStartToIndex Then
    For i = 0 To Index - 1
      If i < Index - 1 Then
        ZW = ZW & Cache(i) & Separator
      Else
        ZW = ZW & Cache(i)
      End If
    Next i
    GetStr = ZW
    Exit Function
  End If
 
  If SelectAllFromIndexToEnd Then
    For i = Index - 1 To Stellen
      If i < Stellen Then
        ZW = ZW & Cache(i) & Separator
      Else
        ZW = ZW & Cache(i)
      End If
    Next i
    GetStr = ZW
    Exit Function
  End If
 
  GetStr = Cache(Index - 1)
  Exit Function
 
ExitByError:
  GetStr = OnErrorReturnString
End Function

Und noch eine kleine Hilfs-Funktion:

Public Function Stellen(ByVal Text As String, _
  ByVal Separator As String, _
  Optional ByVal OnErrorReturnValue As Long = -1) _
  As Long
 
  ' Gibt die Anzahl der Stellen zurück, die via
  ' Trennzeichen markiert sind :-)
  ' Wird das Trennzeichen nicht gefunden,
  ' wird 1 zurückgegeben.
 
  Dim i As Long
  Dim Cache() As String
 
  On Error GoTo ExitByError
  If Len(Separator) = 0 Or Len(Text) = 0 Then
    Stellen = OnErrorReturnValue
    Exit Function
  End If
 
  If InStr(1, Text, Separator) = 0 Then
    Stellen = 1
    Exit Function
  End If
 
  If Len(Separator) >= Len(Text) Then
    Stellen = OnErrorReturnValue
    Exit Function
  End If
 
  Cache = Split(Text, Separator)
  Stellen = UBound(Cache()) + 1
  Exit Function
 
ExitByError:
  Stellen = OnErrorReturnValue
End Function

Die Beschreibung zur Anwendung der Funktionen entnehmen Sie bitte den Kommentaren im Funktions-Kopf.

Die Funktion GetStr eignet sich aber nicht nur für das Extrahieren einzelner Ordnernamen aus einer Pfadangabe, sondern für alle Strings, die sich aus Einzelstrings (durch ein bestimmtes Trennzeichen) zusammensetzen.
 

Dieser Tipp wurde bereits 11.491 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel