Mauszeiger mittig auf ein Control positionieren Dieser Tipp zeigt, wie sich der Mauszeiger per Code mittig auf ein bestimmtes Control positionieren lässt.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  13.223
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 16 Bewertung insgesamt: nützlich Durchschnittliche Bewertung: 3.4 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Nehmen wir an, Sie haben ein Dialogfenster mit mehreren Schaltflächen erstellt (z.B. eine eigene MsgBox). Wird das Fenster angezeigt soll nun der Mauszeiger autom. mittig auf die aktive Schaltfläche platziert werden.

Dieses Vorhaben lässt sich in Verbindung mit der SetCursorPos API-Funktion relativ einfach realisieren. Die Funktion erwartet als Parameter die beiden x-/y-Koordinaten bezogen auf den Desktop (Screen), welche wir mit Hilfe der GetWindowRect-Funktion zurückgeliefert bekommen.

Fügen Sie nachfolgenden Code in ein Modul ein:

Option Explicit
 
' benötigte API-Deklarationen
Private Type POINTAPI
  x As Long
  y As Long
End Type
 
Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type
 
Private Declare Function SetCursorPos Lib "user32" ( _
  ByVal x As Long, _
  ByVal y As Long) As Long
 
Private Declare Function GetWindowRect Lib "user32" ( _
  ByVal hWnd As Long, _
  lpRect As RECT) As Long

' Mauszeiger mittig auf ein Objekt positionieren
Public Sub SetCursorOnObject(ByVal hWnd As Long)
  Dim P As POINTAPI
  Dim R As RECT
 
  ' Größe und Position des Objekts
  GetWindowRect hWnd, R
 
  ' Mauszeiger mittig setzen
  P.x = R.Left + (R.Right - R.Left) / 2
  P.y = R.Top + (R.Bottom - R.Top) / 2
 
  ' Mauszeiger positionieren
  SetCursorPos P.x, P.y
End Sub

Beispiel:
Fügen Sie dem Projekt eine neue Form hinzu und platzieren darauf mehrere CommandButtons. Beim Anzeigen der Form soll der Mauszeiger dann mittig auf den aktiven CommandButton positioniert werden.

Private Sub Form_Activate()
  Static bAlreadyDone As Boolean
 
  ' Sicherstellen, dass der Mauszeiger
  ' nur beim ersten Anzeigen der Form
  ' auf das Objekt positoniert wird
  If Not bAlreadyDone Then
    ' Mauszeiger auf aktives Objekt setzen, 
    ' falls es sich um einen CommandButton handelt
    If TypeOf Me.ActiveControl Is CommandButton Then
      SetCursorOnObject Me.ActiveControl.hWnd
    End If
    bAlreadyDone = True
  End If
End Sub