Verzeichnisse im Treeview darstellen Wie man unter VB.NET das veraltete DirListBox-Control mit wenig Aufwand ersetzen kann, erfahren Sie hier.
Autor:   Lars Konschak	Bewertung:     [ Jetzt bewerten ]	Views:  31.999
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 35 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.0 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

VB.NET stellt keine Steuerelemente bereit, welches die DirListbox aus VB6 ersetzt. Ein Einbinden dieses alten Controls wäre desweiteren nicht wünschenswert. Wer weis, ob dieses in der Zukunft noch von VB.NET unterstüzt wird und ausserdem sieht dieses Control doch sehr verstaubt aus. Es ist aber gar nicht schwer, solch ein Control zu ersetzten. Um die DirListbox zu ersetzten, benötigen wir lediglich ein einfaches Treeview-Control.

Auf die Anzeige der entsprechenden Icons und die Bezeichnung der Laufwerke habe ich hier verzichtet (siehe: Icons der Standartverknüpfung; über das WMI-Objekt kann man z.B die Laufwerknamen ermitteln). Im Treeview werden die Verzeichnisse und die Laufwerke angezeigt. Desweiteren wird ein "+" Zeichen angezeigt, falls das Verzeichnis weitere Unterverzeichnisse enthält (das fehlte zum Beispiel bei der DirListbox).

Private Sub Form1_Load(ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles MyBase.Load
 
  Dim Drive As String
  Dim tn As TreeNode
 
  Dim Verzeichnis As IO.DirectoryInfo
 
  ' Wiedergabe der logischen Laufwerke des PCs
  For Each Drive In Environment.GetLogicalDrives
 
    ' Laufwerk wird als Rootknoten dem Treeview hinzugefügt
    tn = TreeView1.Nodes.Add(Drive)
 
    ' In der Tag-Eigenschaft kann man alle möglichen Daten 
    ' und Objekte speichern. Hier wäre z.B beim Erstellen
    ' eines Explorers der Pfad von Interesse, um z.B im 
    ' ListView die Daten anzuzeigen. Wir brauchen hier aber 
    ' die Pfadangabe für das spätere Hinzufügen von 
    ' Unterverzeichnisse im Treeview 
    tn.Tag = Drive
 
    ' Falls das Laufwerk Unterverzeichnisse besitzt, 
    ' soll das "+" Zeichen eingeblendet werden
    Try
      For Each Verzeichnis In New _
        IO.DirectoryInfo(Drive).GetDirectories
 
        ' Hinzufügen eines Dummyknotens
        tn.Nodes.Add(Verzeichnis.Name)
 
        ' Es reicht ein ermitteltes Unterverzeichnis 
        ' aus, um das  "+" zu erzeugen"
        Exit For
      Next
    Catch
    End Try
  Next
End Sub

Private Sub trvVerzeichnis_BeforeExpand( _
  ByVal sender As System.Object, _
  ByVal e As System.Windows.Forms.TreeViewCancelEventArgs) _
  Handles TreeView1.BeforeExpand
 
  ' Bevor der Knoten expandiert, ermitteln wir den 
  ' Knoten. Wir können dann vorab alle Unterverzeichnisse
  ' und deren Unterverzeichnisse (es wird aber nur das 
  ' erste Unterverzeichnis eingelesen) über die Prozedur 
  ' Read_Directory einlesen. Beim anschliessenden Expandieren 
  ' des(Knoten) werden dann bei Vorhandensein von 
  ' Unterverzeichnissen die "+" 'Zeichen angezeigt.
 
  Dim tn As TreeNode
 
  tn = e.Node
  Read_Directory(tn)
End Sub

Private Sub Read_Directory(ByVal Knoten As TreeNode)
  ' Erstellen eines DirectoryInfo-Objektes, um 
  ' die Unterverzeichnisse einzulesen.
  ' Die benötigte Pfadangabe zum Erzeugen des Objekts 
  ' ermitteln wir aus der Tag-Eigenschaft des Knotens 
  ' (siehe Form1_Load). Wichtig ist, dass der Inhalt 
  ' der Tag-Eigenschaft erst mit der Methode CType in 
  ' den entsprechenden Typ konvertiert werden muss!!
  Dim Verzeichnis As New _
    IO.DirectoryInfo(CType(Knoten.Tag, String))
 
  Dim Unterverzeichnis As IO.DirectoryInfo
  Dim Dummyverzeichnis As IO.DirectoryInfo
 
  Dim tn, xn As TreeNode
 
  ' Ein Flackern des Treeview soll vermieden werden
  TreeView1.BeginUpdate()
 
  ' Der zuvor erzeugte Dummyknoten wird wieder entfernt, 
  ' da dieser beim Einlesen sonst doppelt vorhanden wäre
  Knoten.Nodes.Clear()
 
  Try
    Me.Cursor = Cursors.WaitCursor
 
    For Each Unterverzeichnis In Verzeichnis.GetDirectories
      tn = Knoten.Nodes.Add(Unterverzeichnis.Name)
      tn.Tag = Unterverzeichnis.FullName
 
      ' Falls das Unterverzeichnis weitere Unterverzeichnisse 
      ' besitzt, soll das "+" Zeichen eingeblendet werden
      Try
        For Each Dummyverzeichnis In New _
          IO.DirectoryInfo(Unterverzeichnis.FullName).GetDirectories
 
          ' Hinzufügen eines Dummyknotens
          tn.Nodes.Add(Verzeichnis.Name)
 
          ' Es reicht ein ermitteltes Unterverzeichnis 
          ' aus, um das  "+" zu erzeugen"
          Exit For
        Next
 
      Catch
      End Try
    Next
  Catch
  End Try
 
  TreeView1.EndUpdate()
  Me.Cursor = Cursors.Default
End Sub