Public Class frmTreeView
 
    Dim WithEvents trv As New TreeView With _
        {.Parent = Me, .Top = 50, .Width = 300, .Height = 300}
 
    Dim WithEvents txtNode As New TextBox With _
        {.Parent = Me, .Width = 300}
 
    Dim nodeclicked As TreeNode
 
 
    Private Sub trv_Click(sender As Object, _
        e As System.EventArgs) Handles trv.Click
 
        Dim ht As TreeViewHitTestInfo = _
            trv.HitTest(trv.PointToClient(MousePosition))
 
        nodeclicked = ht.Node 'angeclickter Knoten
 
        If nodeclicked IsNot Nothing Then
            txtNode.Text = nodeclicked.Text
        Else
            txtNode.Text = ""
        End If
    End Sub
 
 
    Private Sub txtNode_KeyDown(sender As Object, _
        e As System.Windows.Forms.KeyEventArgs) Handles txtNode.KeyDown
 
        'Übertragung des Textes aus der Textbox in den Knoten 
        If nodeclicked Is Nothing Then Exit Sub
        If String.IsNullOrWhiteSpace(txtNode.Text) Then Exit Sub
        If e.KeyCode = Keys.Return Then
            nodeclicked.Text = txtNode.Text
        End If
    End Sub
 
 
    Private Sub frmTreeView_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        Dim inilines As String() = _
            IO.File.ReadAllLines _
           ("C:\Daten\IniMasch.txt", System.Text.Encoding.UTF7)
 
        Dim hgr, ugr, sec As TreeNode
        hgr = Nothing : ugr = Nothing : sec = Nothing
        For i As Integer = 0 To inilines.Length - 2
            With inilines(i + 1)
                If inilines(i).StartsWith("[HGR") Then
                    hgr = trv.Nodes.Add(.Substring(.IndexOf("="c) + 1))
                    ugr = Nothing
                End If
 
                If inilines(i).StartsWith("[UGR") Then
                    ugr = hgr.Nodes.Add((.Substring(.IndexOf("="c) + 1)))
                End If
 
                If inilines(i).StartsWith("[SEC") Then
                    If ugr Is Nothing Then
                        ugr = hgr.Nodes.Add("Keine Angabe zur Maschine")
                    End If
                    sec = ugr.Nodes.Add((.Substring(.IndexOf("="c) + 1)))
                End If
            End With
 
            With inilines(i)
                If .ToUpper.StartsWith("VAL=") Then
                    sec.Nodes.Add((.Substring(.IndexOf("="c) + 1)))
                End If
            End With
        Next i
    End Sub
 
End Class