Public Class frmTreeView3
 
    Dim trv As New TreeView With _
            {.Parent = Me, .Width = 300, .Height = 300}
 
 
    Private Class NodeNaming
        Implements IEquatable(Of NodeNaming)
 
        Public Property FileKeyName As String = ""
        Public Property NodeText As String = ""
 
        Public Function Equals1(other As NodeNaming) As Boolean _
            Implements System.IEquatable(Of NodeNaming).Equals
            'case-insensitiver Vergleich anhand der Schlüsselbezeichnung
            Return Me.FileKeyName.ToUpper.Equals(other.FileKeyName.ToUpper)
        End Function
    End Class
 
 
    Private Sub frmTreeview2_Load(sender As System.Object, _
                              e As System.EventArgs) Handles MyBase.Load
 
        Dim line As String
        Dim enc As System.Text.Encoding = System.Text.Encoding.UTF8
        Dim achse, val As TreeNode
        achse = Nothing
 
        'Array: zu ladende Datei-Schlüssel und deren zugeordnete Node-Texte
        Dim suche(4) As NodeNaming
        suche(0) = New NodeNaming With _
               {.FileKeyName = "Betriebsart", .NodeText = "Betriebsart"}
        suche(1) = New NodeNaming With _
               {.FileKeyName = "SollPosition1", .NodeText = "SOLL POS 1"}
        suche(2) = New NodeNaming With _
               {.FileKeyName = "SollPosition2", .NodeText = "SOLL POS 2"}
        suche(3) = New NodeNaming With _
               {.FileKeyName = "VAL_PAR1", .NodeText = "Sollwert Min."}
        suche(4) = New NodeNaming With _
               {.FileKeyName = "VAL_PAR2", .NodeText = "Sollwert Max."}
 
 
        Using sr As New IO.StreamReader("C:\Daten\Achsen1.txt", enc, False)
            Do
                line = sr.ReadLine
                If line.Trim.StartsWith("[ACHSE") Then
                    achse = trv.Nodes.Add(line.Trim("["c, "]"c))
                Else
                    'Schlüssel und Wert splitten
                    Dim parts() As String = line.Split("="c)
                    If parts.Length = 2 Then
                        'gewählter Schlüssel? 
                        Dim i As Integer = Array.IndexOf(suche, _
                             New NodeNaming With {.FileKeyName = parts(0)})
                        If i > -1 Then
                            'Schlüsselknoten mit zugeordn. Bezeichnung 
                            val = achse.Nodes.Add(suche(i).NodeText)     
                                val.Nodes.Add(parts(1)) 'Wert-Knoten
                        End If
                    End If
                End If
            Loop While Not sr.EndOfStream
        End Using
    End Sub
 
End Class