vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Zippen wie die Profis!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück

 Sie sind aktuell nicht angemeldet.Funktionen: Einloggen  |  Neu registrieren  |  Suchen

VB.NET - Ein- und Umsteiger
Demo-Formular zur Bitmap-Freigabe 
Autor: Manfred X
Datum: 11.11.23 08:07

Public Class Form1
 
    Dim pb As New PictureBox With
        {.Parent = Me, .Top = 10, .Left = 10, .Width = 300, .Height = 300,
        .SizeMode = PictureBoxSizeMode.Zoom, .BackColor = Color.White,
        .BorderStyle = BorderStyle.Fixed3D}
 
    Dim WithEvents btnCreateBitmap As New Button With
        {.Parent = Me, .Top = 320, .Left = 10, .Width = 300, .Text = "Create"}
    Dim WithEvents btnKillBitmap As New Button With
        {.Parent = Me, .Top = 360, .Left = 10, .Width = 300, .Text = "Kill"}
    Dim WithEvents btnSaveBitmap As New Button With
        {.Parent = Me, .Top = 400, .Left = 10, .Width = 300, .Text = "Save"}
 
    Dim Gleisplan As Bitmap
    Dim rndm As New Random(Now.Millisecond)
 
 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
 
        Me.MinimumSize = New Size(350, 500)
    End Sub
 
 
    Private Sub CreateBitmap()
 
        DeleteBitmap() 'Freigabe sicher stellen
 
        Dim Gpx, GPy, x1, y1, x2, y2 As Integer
        Gpx = 24361
        GPy = 5966
 
        Gleisplan = New Bitmap(Gpx, GPy,
             Imaging.PixelFormat.Format32bppArgb)
 
        pb.Image = Gleisplan
 
        Using g As Graphics = Graphics.FromImage(Gleisplan),
                pn As New System.Drawing.Pen(Color.Blue, 8)
            g.Clear(Color.Yellow)
            For i As Integer = 0 To 10
                x2 = x1
                y2 = y1
                x1 = CInt(rndm.NextDouble() * Gpx)
                y1 = CInt(rndm.NextDouble() * GPy)
                g.DrawLine(pn, x1, y1, x2, y2)
            Next i
        End Using
 
    End Sub
 
 
    Private Sub SaveBitmap()
        If Gleisplan Is Nothing Then Exit Sub
 
        Dim filepath As String = "G:\downloads\gleisplan.png"
        IO.File.Delete(filepath)
        Gleisplan.Save(filepath, Drawing.Imaging.ImageFormat.Png)
    End Sub
 
 
    Private Sub DeleteBitmap()
 
        'Referenz in der Picturebox aufheben
        pb.Image = Nothing
 
        If Gleisplan IsNot Nothing Then
            'Windows-Resourcen (Handles etc.) der Bitmap entfernen
            Gleisplan.Dispose
            'Letzte Referenz auf die Bitmap aufheben
            '(Löschen der Net-Klasse anfordern)
            Gleisplan = Nothing
        End If
    End Sub
 
    Private Sub btnKillBitmap_Click(sender As Object, e As EventArgs) Handles _
      btnKillBitmap.Click
        DeleteBitmap()
    End Sub
 
    Private Sub btnCreateBitmap_Click(sender As Object, e As EventArgs) Handles _
      btnCreateBitmap.Click
        CreateBitmap()
    End Sub
 
    Private Sub btnSaveBitmap_Click(sender As Object, e As EventArgs) Handles _
      btnSaveBitmap.Click
        SaveBitmap()
    End Sub
End Class
alle Nachrichten anzeigenGesamtübersicht  |  Zum Thema  |  Suchen

 ThemaViews  AutorDatum
PictureBox Maximale Größe512BasicOpa08.11.23 14:05
Re: PictureBox Maximale Größe211Manfred X08.11.23 15:21
Re: PictureBox Maximale Größe166BasicOpa09.11.23 17:54
Re: PictureBox Maximale Größe180Manfred X09.11.23 19:09
Re: PictureBox Maximale Größe206BasicOpa10.11.23 13:59
Re: PictureBox Maximale Größe212Manfred X10.11.23 14:31
Demo-Formular zur Bitmap-Freigabe181Manfred X11.11.23 08:07
Re: Demo-Formular zur Bitmap-Freigabe214BasicOpa11.11.23 14:19
Re: Demo-Formular zur Bitmap-Freigabe145Manfred X11.11.23 15:42
Re: Demo-Formular zur Bitmap-Freigabe183BasicOpa12.11.23 15:35
Re: Demo-Formular zur Bitmap-Freigabe199Manfred X12.11.23 16:44
Re: Demo-Formular zur Bitmap-Freigabe200BasicOpa13.11.23 00:06
Re: Demo-Formular zur Bitmap-Freigabe147BasicOpa13.11.23 14:26
Re: Demo-Formular zur Bitmap-Freigabe170Manfred X13.11.23 17:15
Re: PictureBox Maximale Größe179sv0001013.11.23 20:18
Re: PictureBox Maximale Größe148Manfred X13.11.23 21:16
Re: PictureBox Maximale Größe166Kuno6014.11.23 00:09
Re: PictureBox Maximale Größe202Manfred X14.11.23 05:20
Re: PictureBox Maximale Größe233sv0001014.11.23 07:47
Re: PictureBox Maximale Größe194Manfred X14.11.23 08:37
Re: PictureBox Maximale Größe162Kuno6015.11.23 12:17
Re: PictureBox Maximale Größe139Manfred X15.11.23 13:55
Re: PictureBox Maximale Größe172BasicOpa15.11.23 17:25
Re: PictureBox Maximale Größe138Manfred X15.11.23 21:50

Sie sind nicht angemeldet!
Um auf diesen Beitrag zu antworten oder neue Beiträge schreiben zu können, müssen Sie sich zunächst anmelden.

Einloggen  |  Neu registrieren

Funktionen:  Zum Thema  |  GesamtübersichtSuchen 

nach obenzurück
 
   

Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel