Imports System.ComponentModel
 
Public Class ResetClass
    Implements System.ComponentModel.INotifyPropertyChanged
 
    Public Event PropertyChanged(sender As Object, _
                                 e As PropertyChangedEventArgs) _
    Implements INotifyPropertyChanged.PropertyChanged
 
    Private Class Members
        Implements ICloneable
 
        Public Property Name As String = ""
        Public Property Beruf As String = ""
        Public Property Alter As Integer = 0
 
 
        Public Function Clone() As Object _
            Implements System.ICloneable.Clone
 
            Dim c As Members = CType(Me.MemberwiseClone, Members)
            Return c
        End Function
    End Class
 
    'Interne Datenklassen
    Dim dialog As New Members    'temporär
    Dim committed As New Members 'bestätigt 
 
 
    ' Properties für den Dialog
    '===========================
 
    Public Property NameD As String
        Set(value As String)
            dialog.Name = value
            RaiseEvent PropertyChanged _
                 (Me, New PropertyChangedEventArgs("NameD"))
        End Set
        Get
            Return dialog.Name
        End Get
    End Property
 
    Public Property BerufD As String
        Set(value As String)
            dialog.Beruf = value
            RaiseEvent PropertyChanged _
                (Me, New PropertyChangedEventArgs("BerufD"))
        End Set
        Get
            Return dialog.Beruf
        End Get
    End Property
 
    Public Property AlterD As Integer
        Set(value As Integer)
            dialog.Alter = value
            RaiseEvent PropertyChanged _
                (Me, New PropertyChangedEventArgs("AlterD"))
        End Set
        Get
            Return dialog.Alter
        End Get
    End Property
 
 
    'Properties für bestätigte Daten
    '==================================
 
    Public Property Name As String
        Set(value As String)
            committed.Name = value
            RaiseEvent PropertyChanged _
               (Me, New PropertyChangedEventArgs("Name"))
        End Set
        Get
            Return committed.Name
        End Get
    End Property
 
    Public Property Beruf As String
        Set(value As String)
            committed.Beruf = value
            RaiseEvent PropertyChanged _
                (Me, New PropertyChangedEventArgs("Beruf"))
        End Set
        Get
            Return committed.Beruf
        End Get
    End Property
 
    Public Property Alter As Integer
        Set(value As Integer)
            committed.Alter = value
            RaiseEvent PropertyChanged _
                (Me, New PropertyChangedEventArgs("Alter"))
        End Set
        Get
            Return committed.Alter
        End Get
    End Property
 
    Private Sub copymembers(ByVal q As Members, ByRef z As Members)
        z = CType(q.Clone, Members)
        RaiseEvent PropertyChanged _
            (Me, New PropertyChangedEventArgs(Nothing))
    End Sub
 
    Public Sub Reset()
        copymembers(committed, dialog)
    End Sub
 
    Public Sub Commit()
        copymembers(dialog, committed)
    End Sub
 
End Class