HTTP Dateidownload mit VB.NET Dieser Tipp zeigt, wie sich Dateien via HTTP herunterladen lassen, inkl. Fortschrittanzeige.
Autor:   Stefan Mähr	Bewertung:     [ Jetzt bewerten ]	Views:  37.922
www.visualsoft-net.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 29 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.2 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Wie einfach gewisse Aufgaben mit dem .NET Framework geworden sind, zeigt dieses Beispiel eines HTTP-Dateidownloads mit den Klassen aus dem Namespace System.NET.

Dazu erstellen wir ein Windows Forms Projekt und ziehen folgende Controls auf das Forumlar:

1. Label mit dem Namen lblURL und der Text-Eigenschaft "URL"
2. Textbox mit dem Name txtURL
3. Command mit dem Namen cmdDownload und Text "Download"
4. Progressbar mit der Eigenschaft Docked "Bottom"

In der Codeansicht importieren wir folgende Namespaces:

Imports System.Net
Imports System.IO

Im ButtonClick Ereignis des cmdDownload-Buttons setzen wir folgenden Code:

Private Sub cmdDownload_Click(ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles cmdDownload.Click
 
  Dim dlg As New FolderBrowserDialog
  Dim strFile As String
  Dim strFolder As String
 
  ' falls keine URL angegeben, Vorgang abbrechen
  If Me.txtURL.Text.Length = 0 Then Exit Sub
 
  Dim strPathParts() As String = Me.txtURL.Text.Split("/")
  strFile = strPathParts(strPathParts.GetUpperBound(0))
 
  ' Ordner-Auswahldialog anzeigen
  If dlg.ShowDialog Then
    strFolder = dlg.SelectedPath
  Else
    Exit Sub
  End If
 
  ' Download starten
  cmdDownload.Enabled = False
  Call DownloadItem(txtURL.Text, strFile, strFolder)
  MsgBox("Download beendet")
  cmdDownload.Enabled = True
  ProgressBar1.Visible = False
End Sub

Hier wird ein Folderbrowserdialog aufgerufen, welcher den Ordner für den Download festlegt und der Dateiname des Downloads ausgelesen.

Der tatsächliche Download wird in der Funktion DownloadItem durchgeführt.

Private Sub DownloadItem(ByVal sURL As String, _
  ByVal strFile As String, ByVal strFolder As String)
 
  Dim webreq As HttpWebRequest
  Dim webresp As HttpWebResponse
  Dim bReader As BinaryReader
  Dim bWriter As BinaryWriter
  Dim stream As FileStream
  Dim buffer() As Byte = New Byte(1024) {}
  Dim bytesRead As Integer
 
  ' Fortschritt zunächst auf 0% setzen
  Me.ProgressBar1.Value = 0
 
  Try
    ' Datei-Download via HTTP "anfordern"
    webreq = HttpWebRequest.Create(sURL)
    webresp = webreq.GetResponse
 
    ' Download-Größe
    Me.ProgressBar1.Maximum = webresp.ContentLength
 
    ' lokale Datei öffnen
    stream = New FileStream(strFolder & "\" & strFile, FileMode.Create)
    bReader = New BinaryReader(webresp.GetResponseStream)
    bWriter = New BinaryWriter(stream)
 
    ' Datei blockweise downloaden und lokal speichern
    Do
      bytesRead = bReader.Read(buffer, 0, 1024)
      bWriter.Write(buffer, 0, bytesRead)
      ProgressBar1.Value += bytesRead
      ProgressBar1.Update()
    Loop Until bytesRead = 0
 
    ' alle Dateien schließen
    bWriter.Close()
    bReader.Close()
    stream.Close()
 
  Catch ex As Exception
    ' Bei Fehler...
    MessageBox.Show("Fehler: " & vbCrLf & ex.Message, _
      "Fehler", MessageBoxButtons.OK, _
      MessageBoxIcon.Error, MessageBoxDefaultButton.Button1)
  End Try
End Sub