vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
vb@rchiv Offline-Reader - exklusiv auf der vb@rchiv CD Vol.4  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2020
 
zurück
Rubrik: System/Windows · Sonstiges   |   VB-Versionen: VB5, VB628.01.05
Windowsversion inkl. ServicePack ermitteln

Dieser Tipp zeigt, wie sich die Windowsversion einschl. ServicePack ermitteln lässt

Autor:   Microsys KramerBewertung:     [ Jetzt bewerten ]Views:  11.101 
www.access-paradies.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Mit diesem Tipp lässt sich sowohl die Windowsversion, als auch die Build-Nr. und das installierte ServicePack ermitteln.
Fügen Sie hierzu nachfolgenden Code in ein Modul ein:

Option Explicit
 
' benötigte API-Deklarationen
Private Const VER_PLATFORM_WIN32s = 0
Private Const VER_PLATFORM_WIN32_WINDOWS = 1
Private Const VER_PLATFORM_WIN32_NT = 2
 
Private Type OSVERSIONINFO
  OSVSize         As Long
  dwVerMajor      As Long
  dwVerMinor      As Long
  dwBuildNumber   As Long
  PlatformID      As Long
  szCSDVersion    As String * 128
End Type
 
Private Declare Function GetVersionEx Lib "kernel32" _
  Alias "GetVersionExA" ( _
  lpVersionInformation As OSVERSIONINFO) As Long
 
 
Public Type WINVER
  OSVersion   As String
  BuildNr     As String
  ServicePack As String
End Type
' Windowsversion, Build-Nr und ServicePack ermitteln
Public Function GetWinVersion() As WINVER
  On Error GoTo ErrHandler
 
  Dim osv As OSVERSIONINFO
  Dim nPos As Integer
  Dim sVer As String
  Dim sBuild As String
 
  With GetWinVersion
    osv.OSVSize = Len(osv)
    If GetVersionEx(osv) = 1 Then
      Select Case osv.PlatformID
        Case VER_PLATFORM_WIN32s
          .OSVersion = "Win32s"
        Case VER_PLATFORM_WIN32_NT
          .OSVersion = "Windows NT"
          Select Case osv.dwVerMajor
            Case 5:
              Select Case osv.dwVerMinor
                Case 0
                   .OSVersion = "Windows 2000"
                Case 1 
                   .OSVersion = "Windows XP"
              End Select
          End Select
        Case VER_PLATFORM_WIN32_WINDOWS:
          Select Case osv.dwVerMinor
            Case 0
              .OSVersion = "Windows 95"
            Case 90
              .OSVersion = "Windows ME"
            Case Else
              .OSVersion = "Windows 98"
          End Select
      End Select
 
      .BuildNr = CSTR(osv.dwBuildNumber And &HFFFF&)
      nPos = InStr(osv.szCSDVersion, Chr$(0))        
      If nPos Then
        .ServicePack = Left$(osv.szCSDVersion, nPos - 1)
      Else
        .ServicePack = "Kein Servicepack"
      End If
    End If
  End With
  On Error Goto 0
 
ErrHandler:
End Function

Beispielaufruf:

Dim tWinVer As WINVER
tWinVer = GetWinVersion()
 
With tWinVer
  List1.AddItem "OSVersion: " & .OSVersion
  List1.AddItem "Build: " & .BuildNr
  List1.AddItem "ServicePack: " & .ServicePack
End With

Dieser Tipp wurde bereits 11.101 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2020 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel