vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevDataGrid - Gönnen Sie Ihrem SQL-Kommando diesen krönenden Abschluß!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Maus & Tastatur · Drag & Drop   |   VB-Versionen: VB608.06.05
Drag & Drop zweier ListBox-Controls

Wie man Elemente von einer ListBox via Drag & Drop in eine zweite kopiert und dazu noch die Zielposition berücksichtigt, das erfahren Sie hier.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  10.316 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Heute möchten wir Ihnen zeigen, wie man mehrere selektierte ListBox-Einträge einer Ausgangs-ListBox in eine zweite ListBox kopiert - und zwar via Drag & Drop. Das bedeutet also, dass die selektierten Einträge einfach durch Ziehen der Maus und Loslassen auf der 2. ListBox kopiert werden sollen. Weiterhin sollen die Einträge dann exakt an der Position eingefügt, über der sich der Mauszeiger befindet, wenn die Maustaste losgelassen wird.

Erstellen Sie ein neues Projekt mit zwei ListBox-Controls und setzen die MultiSelect-Eigenschaft von "List1" auf "2 - erweitert".

Fügen Sie nachfolgenden Code in den Codeteil der Form ein:

Option Explicit
 
' benötigte API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Long) As Long
 
Private Const LB_GETTOPINDEX = &H18E
Private Const LB_GETITEMHEIGHT = &H1A1
Private Sub Form_Load()
  Dim i As Long
 
  ' ein paar Testeinträge erstellen
  For i = 1 To 100
    List1.AddItem "Eintrag " & CStr(i)
  Next i
 
  ' Wichtig: das korrekte Setzen von OLEDragMode bzw. OLEDropMode
  List1.OLEDragMode = 1 ' manuell
  List2.OLEDropMode = 1 ' manuell
End Sub
Private Sub List2_OLEDragDrop(Data As DataObject, Effect As Long, _
  Button As Integer, Shift As Integer, X As Single, Y As Single)
 
  Dim i As Long
  Dim sData() As String
  Dim nTopIndex As Long
  Dim nItemHeight As Long
  Dim nCount As Long
  Dim nIndex As Long
 
  ' Handelt es bei den Quelldaten um "Textdaten"?
  If Data.GetFormat(vbCFText) Then
 
    With List2
      ' Ermitteln des ersten Index der Listbox
      nTopIndex = SendMessage(.hwnd, LB_GETTOPINDEX, 0, 0)
 
      ' Ermitteln der Item-Zeichenhöhe
      nItemHeight = SendMessage(.hwnd, LB_GETITEMHEIGHT, 0, 0) * Screen.TwipsPerPixelY
 
      ' Anzahl sichtbarer Einträge
      nCount = .Height / nItemHeight
      If .Height Mod nItemHeight <> 0 Then nCount = nCount + 1
 
      ' Ermitteln des Index, über dem der Mauspfeil steht
      nIndex = nTopIndex - 1
      For i = 0 To .Height Step nItemHeight
        If i > Y Then Exit For
        nIndex = nIndex + 1
      Next
      If nIndex > .ListCount - 1 Then nIndex = .ListCount
 
      ' alle Einträge in List2 kopieren
      sData = Split(Data.GetData(vbCFText), vbCrLf)
      For i = 0 To UBound(sData)
        List2.AddItem sData(i), nIndex + i
      Next i
 
    End With
  End If
End Sub

Dieser Tipp wurde bereits 10.316 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel