Aktuellen Fensterinhalt drucken (.NET) Hier werden zwei Möglichkeiten vorgestellt, wie man die aktuelle Form in ein Bitmap kopieren und ausdrucken kann.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  28.810
www.tools4vb.de	System:  WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 10 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Heute möchten wir Ihnen zwei Möglichkeiten vorstellen, wie sich der Inhalt der aktiven Form ausdrucken lässt.

1. Screenshot per Zwischenablage erstellen und drucken
Über die Tastenkombination ALT+Druck lässt sich bekanntlich ein Screenshot des aktiven Fensters erstellen und in die Zwischenablage kopieren. Über das Clipboard-Objekt kann man das Bild dann in ein Bitmap-Objekt kopieren und entsprechend weiterverarbeiten.

Public Class Form1
  ' Bitmap-Objekt für die aktuelle Form
  Dim oBitmap As Bitmap
 
  ' Objekte für Ausdruck/Seitenvorschau
  Dim WithEvents PrintDocument As New Printing.PrintDocument
  Dim PrintPreview As New PrintPreviewDialog

  ' aktiven Fensterinhalt per ALT+Druck in die 
  ' Zwischenablage kopieren und ausdrucken
  Private Sub Button1_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button1.Click
 
    ' Screenshot des aktiven Fensters erstellen
    SendKeys.Send("%({PRTSC})")
    SendKeys.Flush()
 
    ' Bitmap-Objekt aus Zwischenablage kopieren
    oBitmap = CType(Clipboard.GetImage(), Bitmap)
 
    ' in Seitenvorschau anzeigen
    With PrintPreview
      .Document = PrintDocument
      .ShowDialog()
    End With
  End Sub

  ' Hier erfolgt der Ausdruck des Bitmaps
  Private Sub PrintDocument_PrintPage(ByVal sender As Object, _
    ByVal e As System.Drawing.Printing.PrintPageEventArgs) _
    Handles PrintDocument.PrintPage
 
    ' Bitmap-Objekt drucken
    Dim gr As Graphics = e.Graphics
    gr.DrawImageUnscaled(oBitmap, e.MarginBounds.X, e.MarginBounds.Y)
    e.HasMorePages = False
 
    ' Bitmap zerstören
    oBitmap.Dispose()
  End Sub
 
Enc Class

2. Bildschirmausschnitt über die CopyFromScreen-Methode erstellen und drucken
Die nachfolgende Variante zeigt, wie sich ein bestimmter Bereich des aktuellen Screens (Desktops) in ein Bitmap-Objekt kopieren lässt, so dass die Zwischenablage für den Ausdruck des Fensterinhaltes "unberührt" bleibt.

Public Class Form1
  ' Bitmap-Objekt für die aktuelle Form
  Dim oBitmap As Bitmap
 
  ' Objekte für Ausdruck/Seitenvorschau
  Dim WithEvents PrintDocument As New Printing.PrintDocument
  Dim PrintPreview As New PrintPreviewDialog

  ' Bitmap durch Kopieren des Desktop-Ausschnitts erstellen
  Private Sub Button2_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button2.Click
 
    ' Rechteck in der benötigten Größe erstellen
    Dim oRect As New Rectangle(Me.Left, Me.Top, Me.Width, Me.Height)
 
    ' Bitmap-Objekt erstellen
    With oRect
      oBitmap = New Bitmap(.Width, .Height, Imaging.PixelFormat.Format24bppRgb)
    End With
 
    ' Screenshot des Desktops für das ausgewählten Rechteckes erstellen
    Using g As Graphics = Graphics.FromImage(oBitmap)
      g.CopyFromScreen(oRect.Left, oRect.Top, 0, 0, _
        New Size(oRect.Width, oRect.Height))
    End Using
 
    ' in Seitenvorschau anzeigen
    With PrintPreview
      .Document = PrintDocument
      .ShowDialog()
    End With
  End Sub

  ' Hier erfolgt der Ausdruck des Bitmaps
  Private Sub PrintDocument_PrintPage(ByVal sender As Object, _
    ByVal e As System.Drawing.Printing.PrintPageEventArgs) _
    Handles PrintDocument.PrintPage
 
    ' Bitmap-Objekt drucken
    Dim gr As Graphics = e.Graphics
    gr.DrawImageUnscaled(oBitmap, e.MarginBounds.X, e.MarginBounds.Y)
    e.HasMorePages = False
 
    ' Bitmap zerstören
    oBitmap.Dispose()
  End Sub
 
Enc Class