vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v3.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Verschiedenes / Sonstiges   |   VB-Versionen: VB621.12.09
Dateinamen aus der Zwischenablage ermitteln

Mit dieser Funktion lassen sich alle Dateinamen ermitteln, die über den Windows Explorer in die Zwischenablage kopiert wurden.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  11.576 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Wenn man im Windows Explorer eine oder mehrere Dateien auswählt und dann den Befehl "Kopieren" oder "Ausschneiden" wählt, werden alle ausgewählten Dateinamen in die Zwischenablage kopiert. VB selbst bietet jedoch keine Möglichkeit, genau diese in der Zwischenablage befindlichen Dateinamen zu ermitteln.

Mit nachfolgender Funktion möchten wir für Abhilfe schaffen. Die Funktion prüft mittels des Windows API die Zwischenablage auf darin befindliche Dateinamen und gibt diese als String-Array zurück.

Option Explicit
 
' benötigte API-Deklarationen
Private Declare Function IsClipboardFormatAvailable Lib "user32" ( _
  ByVal wFormat As Long) As Long
 
Private Declare Function OpenClipboard Lib "user32" ( _
  ByVal hwnd As Long) As Long
 
Private Declare Function GetClipboardData Lib "user32" ( _
  ByVal wFormat As Long) As Long
 
Private Declare Function DragQueryFile Lib "shell32.dll" _
  Alias "DragQueryFileA" ( _
  ByVal HDROP As Long, _
  ByVal UINT As Long, _
  ByVal lpStr As String, _
  ByVal ch As Long) As Long
 
Private Declare Function CloseClipboard Lib "user32" () As Long
 
Private Const CF_HDROP As Long = 15
Public Function GetClipboardFiles(ByRef Files() As String) As Long
  Dim nHandle As Long
  Dim nCount As Long
  Dim nLen As Long
  Dim sFile As String
 
  Dim nFormat As Long
  Dim hGlobal   As Long
  Dim i As Long
 
  ' Prüfen, ob Dateien in der Zwischenablage vorhanden
  If IsClipboardFormatAvailable(CF_HDROP) > 0 Then
    ' Zwischenablage öffnen
    If OpenClipboard(0) <> 0 Then
      ' Handle holen
      nHandle = GetClipboardData(CF_HDROP)
      If nHandle <> 0 Then
        ' jetzt alle Dateinamen ermitteln
        nCount = DragQueryFile(nHandle, -1, vbNullString, 0)
        ReDim Files(nCount - 1)
        For i = 0 To nCount - 1
          nLen = DragQueryFile(nHandle, i, vbNullString, 0)
          sFile = String$(nLen + 1, 0)
          nLen = DragQueryFile(nHandle, i, sFile, Len(sFile))
          Files(i) = Left$(sFile, nLen)
        Next i
      End If
 
      ' Zwischenablage schließen
      CloseClipboard
    End If
  End If
 
  GetClipboardFiles = nCount
End Function

Aufrufbeispiel:

Dim nCount As Long
Dim sFiles() As String
Dim i  As Long
 
List1.Clear
nCount = GetClipboardFiles(sFiles())
If nCount > 0 Then
  For i = 0 To nCount - 1
    List1.AddItem sFiles(i)
  Next i
Else
  MsgBox "Zwischenablage enthält keine Dateien!", vbInformation
End If

Dieser Tipp wurde bereits 11.576 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Aktuelle Diskussion anzeigen (3 Beiträge)

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel