Dateien miteinander vergleichen Sind zwei Dateien identisch? Diese Frage lässt sich nicht immer beantworten, wenn man nur die reine Dateigröße miteinander vergleicht.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  25.643
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 21 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.8 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Um zu prüfen, ob zwei Dateien identisch sind, sollte man folgendermassen vorgehen:

1. Vergleich der Dateigrößen
2. Haben beide Dateien die gleiche Größe, muss der Inhalt miteinander verglichen werden

Die Funktion FileCompare erledigt genau diese Aufgabe für Sie. Das notwendige Vergleichen der Datei-Inhalte erfolgt im Binärmodus. Hierzu werden beide Dateien mit For Binary geöffnet und blockweise eingelesen. Die Schleife (der Vergleich) wird abgebrochen, sobald die gelesenen "Blöcke" nicht mehr identisch sind.

Rückgabewert der Funktion:

0 - Identical
1 - SizeDifferent
2 - ContentsDifferent

Fügen Sie nachfolgende Code in ein Modul Ihres Projekts ein:

Public Enum FileCompareStatus
  Identical = 0         ' identisch
  SizeDifferent = 1     ' Dateigröße verschieden
  ContentDifferent = 2  ' Inhalte verschieden
End Enum
 
' zwei Dateien miteinander vergleichen
Public Function FileCompare(ByVal sFile1 As String, _
  ByVal sFile2 As String, _
  Optional ByVal picProgress As Control = Nothing) _
  As FileCompareStatus
 
  Dim F1 As Integer
  Dim F2 As Integer
  Dim sTemp1 As String
  Dim sTemp2 As String
  Dim fSize As Long
  Dim rSize As Long
  Dim lSize As Long
  Dim bResult As Boolean
 
  ' Größe eines einzelnen Blocks
  Const BlockSize = 4096
 
  ' Default-Wert der Funktion
  FileCompare = Identical
 
  ' Dateien öffnen
  F1 = FreeFile: Open sFile1 For Binary As #F1
  F2 = FreeFile: Open sFile2 For Binary As #F2
 
  ' zunächst Dateigröße vergleichen
  If LOF(F1) <> LOF(F2) Then
    FileCompare = SizeDifferent
  Else
    ' Inhalt Blockweise einlesen und miteinander
    ' vergleichen
    fSize = LOF(F1)
    rSize = 0
 
    bResult = False
    While rSize <> fSize And Not bResult
      ' Anzahl einzulesender Bytes
      lSize = IIf(rSize + BlockSize > fSize, _
        fSize - rSize, BlockSize)
 
      ' Variablen vorbereiten
      sTemp1 = Space$(lSize)
      sTemp2 = Space$(lSize)
 
      ' Inhalte einlesen
      Get #F1, , sTemp1
      Get #F2, , sTemp2
 
      ' Inhalte vergleichen
      bResult = (sTemp1 <> sTemp2)
      rSize = rSize + lSize
 
      ' Fortschritt anzeigen
      If Not picProgress Is Nothing Then
        ShowProgress picProgress, rSize, 0, fSize
      End If
    Wend
 
    If bResult Then _
      FileCompare = ContentDifferent
  End If
 
  ' Dateien wieder schliessen
  Close #F1: Close #F2
End Function

Für die optionale Fortschrittsanzeige verweise ich an dieser Stelle auf unseren Tipp:
 ProgressBar im Eigenbau

Um die neue Funktion gleich auszuprobieren, erstellen Sie ein neues Projekt und plazieren auf die Form einen CommandButton (cmdCompare), ein Label-Control (lblStatus), sowie ein PictureControl (picProgress).

Beim Klicken auf den CommandButton wird folgender Code ausgeführt:

Private Sub cmdCompare_Click()
  Dim sFile1 As String
  Dim sFile2 As String
 
  ' Hier die beiden Dateien eintragen
  sFile1 = "c:\temp\datei1.ext"
  sFile2 = "c:\temp\datei2.ext"
 
  ' Dateien miteinander vergleichen
  lblStatus.Caption = "Datei-Vergleich läuft..."
  ShowProgress picProgress, 0, 0, 0
  DoEvents
 
  Select Case FileCompare(sFile1, sFile2, picProgress)
    Case Identical
      lblStatus.Caption = "Dateien sind identisch"
    Case SizeDifferent
      lblStatus.Caption = "Dateigrößen unterscheiden sich!"
    Case ContentDifferent
      lblStatus.Caption = "Datei-Inhalte unterscheiden sich!"
  End Select
End Sub