Platzieren Sie auf die Form folgende Steuerelemente:

1. Richtextbox (txtValidate)
2. Commandbutton (cmdValidate)
3. Textbox (txtRegex)

Code:

Option Explicit
 
Private Sub Form_Load()
  ' -> Hier legen wir unseren Testtext fest.
  ' Sie können diesen natürlich beliebig verändern
  txtValidate.Text = "Wir finden ein paar Wörter in einem Text" & _
    vbCrLf & "Wie benütze ich Regular Expressions in VB6?"
End Sub

' Fundstellen farblich kennzeichnen
Private Sub cmdValidate_Click()
  Dim oRegex As RegExp
  Dim m As Match
  Dim strPattern As String
 
  ' --> Pattern einlesen und prüfen
  strPattern = txtRegex.Text
  If Len(Trim(strPattern)) = 0 Then Exit Sub
 
  On Error GoTo ErrHandler
 
  ' --> die Selectionfarbe der Richtextbox zurücksetzen
  With txtValidate
    .SelStart = 1
    .SelLength = Len(.Text)
    .SelColor = vbBlack
  End With
 
  ' --> "Regular-Expression"-Objekt erstellen
  Set oRegex = New RegExp
  With oRegex
    .Pattern = strPattern
    .Global = True
 
    ' --> Alle Matches durchlaufen
    For Each m In .Execute(txtValidate.Text)
      ' --> Gefundene Einträge in der Richtextbox markieren
      With txtValidate
        .SelStart = m.FirstIndex
        .SelLength = m.Length
        .SelColor = vbRed
      End With
    Next 
  End With
 
  ' --> Regex Objekt zerstören
  Set oRegex = Nothing
  Exit Sub
 
ErrHandler:
  MsgBox Err.Description & vbCrLf & Err.Number, vbCritical + vbOKOnly, "Error"
  Set oRegex = Nothing
  Err.Clear
End Sub

Nun kommen wir zum Ausdruck für die Abfrage selbst.

Starten Sie das Projekt probieren einmal folgende "Abfragen" aus:

VB        -> suche nach dem Wort VB im Text
i         -> sucht alle „i" im Text
[0-9]     -> sucht alle numerischen Werte im Text
(ein|ich) -> sucht alle "ein" und "ich" im Text