Eindeutige AutoID Wie man eine eindeutige AutoID für Collections, UDTs oder dynamische Arrays erzeigen kann, das erfahren Sie hier.
Autor:   Roland Wutzke	Bewertung:     [ Jetzt bewerten ]	Views:  13.817
www.vb-power.net	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 11 Bewertung insgesamt: nützlich Durchschnittliche Bewertung: 2.9 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Einige Steuerelemente, wie das TreeView oder ListView, unterstützen Key-Werte zur besseren Identifizierung der Items. Befüllen Sie diese Steuerelemente zur Laufzeit mit z.B. Datei- oder Verzeichnisnamen, kommt es schnell zur Fehlermeldung: Schlüssel nicht eindeutig in der Auflistung und das Programm bricht ab.

Aber nicht nur im TreeView oder ListView lässt sich eine solche eindeutige ID verwenden. Sie werden oft auch in Collections, UDTs und dynamischen Arrays benötigt.

Nachfolgend möchten wir Ihnen zeigen, wie sich eine eindeutige AutoID, ähnlich dem Autowert Feld einer Access DB realisieren lässt.

Die Klasse clsAuotID
Folgende Eigenschaften und Methoden stehen zur Verfügung:

• AutoID: gibt eine eindeutige ID zurück
• LastAutoID: gibt die letzte ID zurück
• ResetID: Reset der AutoID. Optional kann ein Startwert festgelegt werden. Default = 0
• SaveIDToPropertyBag: Die ID wird in einem PropertyBag gespeichert
• LoadIDFromPropertyBag: Die ID wird aus einem PropertyBag geladen

Und hier der Code der Klasse:

' *******************************************************************
' *
' *   AutoID   VB Klassenmodul
' *
' *   Dieses Klassenmodul erzeugt und verwaltet eine eindeutige
' *   AutoID, ähnlich eines AutoWert Feldes einer Access DB. Jedoch
' *   mit dem Unterschied, dass die AutoID zurückgesetzt, bzw. auf
' *   einen Startwert festgelegt werden kann. Ebenso kann die
' *   AutoID in ein PropertyBag geschrieben und auch wieder
' *   ausgelesen werden.
' *
' *   Dezember 2004 - VB-Power.net     www.vb-power.net
' *
' *******************************************************************
 
Option Explicit
 
Private aID As Long

' Klasse initialisieren
Private Sub Class_Initialize()
  ' Anfangswert auf 0 setzen
  aID = 0
End Sub

' neue AutoID holen
Public Function AutoID() As Long
  ' AutoID immer um den Wert 1 erhöhen
  aID = aID + 1
  AutoID = aID
End Function

' letzte AutoID zurückgeben
Public Property Get LastAutoID()
  LastAutoID = aID
End Property

' AutoID zurücksetzen
Public Sub ResetID(Optional StartId As Long = 0)
  aID = StartId
End Sub

' AutoID aus PropertyBag laden
Public Sub LoadIDFromPropertyBag(sFile As String)
  Dim PBag As New PropertyBag
  Dim vTmp As Variant
  Dim F As Long
 
  If Dir$(sFile, vbNormal) <> "" Then
    F = FreeFile
    Open sFile For Binary As #F
    Get #F, , vTmp
    Close #F
 
    With PBag
      .Contents = vTmp
      aID = .ReadProperty("AutoID", 0)
    End With
  End If
End Sub

' AutoID in PropertyBag speichern
Public Sub SaveIDToPropertyBag(sFile As String)
  Dim PBag As New PropertyBag
  Dim F As Long
 
  PBag.WriteProperty "AutoID", aID, 0
 
  F = FreeFile
  Open sFile For Binary As #F
  Put #F, , PBag.Contents
  Close #F
End Sub