Neuzeichnen von Fensterinhalten verhindern Dieser Tipp zeigt, wie Sie unter VB.NET das automatische Neuzeichnen von Fensterinhalten bei Bedarf gezielt ausschalten und später wieder einschalten
Autor:   Roland Wutzke	Bewertung:     [ Jetzt bewerten ]	Views:  17.559
www.vb-power.net	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 9 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 4.9 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Kennen Sie das auch? Der Fensterinhalt flackert, während eine bestimmte Aktion bzw. eine Vielzahl von Aktionen ausgeführt wird?

Wie Sie diesen unangenehmen und störenden Effekt ausschalten, zeigt Ihnen der nachfolgende Tipp.

Der Code zum Ein-/Ausschalten des Neuzeichnens kapseln wir hierzu in einer kleinen Klasse:

Imports System.Runtime.InteropServices
Public Class cLockUpdate
  ' benötigte API-Struktur
  <StructLayout(LayoutKind.Sequential)> _
  Public Structure RECT
    Public Left As Integer
    Public Top As Integer
    Public Right As Integer
    Public Bottom As Integer
  End Structure
 
  ' benötigte API-Funktionen
  <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
  Private Shared Function GetClientRect( _
    ByVal hWnd As System.IntPtr, _
    ByRef lpRECT As RECT) As Integer
  End Function
 
  Declare Auto Function SendMessage Lib "user32.dll" ( _
    ByVal hWnd As IntPtr, _
    ByVal msg As Integer, _
    ByVal wParam As IntPtr, _
    ByVal lParam As IntPtr) As IntPtr
 
  <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
  Private Shared Function RedrawWindow( _
    ByVal hWnd As IntPtr, _
    ByRef lprcUpdate As RECT, _
    ByVal hrgnUpdate As IntPtr, _
    ByVal flags As Int32) As Int32
  End Function
 
  ' API-Konstanten
  Private Const RDW_INVALIDATE As Int32 = &H1
  Private Const WM_SETREDRAW As Int32 = &HB
  Private Const RDW_ALLCHILDREN As Int32 = &H80
  Private Const RDW_UPDATENOW As Int32 = &H100
  Private Const RDW_ERASE As Int32 = &H4

  ''' <summary>
  ''' Deaktiviert / Aktiviert das Neuzeichnen eines Fensters
  ''' </summary>
  ''' <param name="hWnd">Handle des Fensters/Controls</param>
  ''' <param name="wLock">True, um das Neuzeichnen zu verhiner
  ''' False, um das Neuzeichnen wieder zu aktivieren</param>
  Public Shared Sub LockWindow(ByVal hWnd As IntPtr, ByVal wLock As Boolean)
    Dim ClientRect As New RECT
 
    If wLock = True Then
      SendMessage(hWnd, WM_SETREDRAW, False, 0&)
    Else
      SendMessage(hWnd, WM_SETREDRAW, True, 0&)
      GetClientRect(hWnd, ClientRect)
      RedrawWindow(hWnd, ClientRect, 0&, RDW_ERASE Or _
        RDW_INVALIDATE Or RDW_ALLCHILDREN Or RDW_UPDATENOW)
    End If
  End Sub

End Class

Beispiel für den Aufruf:

' Zeit-Messung starten
Dim sw As New Stopwatch
sw.Start()
 
' Neuzeichnen der RichTextBox verhindern
cLockUpdate.LockWindow(Me.RichTextBox1.Handle, True)
 
' ... hier die Aktionen ...
 
' Neuzeichnen wieder aktivieren mit autom. Refersh
cLockUpdate.LockWindow(Me.RichTextBox1.Handle, False)
 
' benötigte Zeit ausgeben 
sw.Stop()
MsgBox("msec: " & sw.ElapsedMilliseconds.ToString)

Hinweis:
Mit Hilfe der LockUpdate-Methode lassen sich nicht nur einzelne Controls, sondern bei Bedarf auch das gesamte Fenster "sperren". Hierzu einfach das Handle der Form übergeben:

' Neuzeichnen des gesamten Fensters sperren
cLockUpdate.LockWindow(Me.Handle, True)
 
' ...
 
' Neuzeichnen wieder aktivieren
cLockUpdate.LockWindow(Me.Handle, False)

Anmerkung:
Einige Controls, wie bspw. ListBox, ListView, ComboBox und CheckedListBox verfügen bereits über obige Funktionalität, so dass man hier nicht extra die LockUpdate-Klasse benötigt.

' Neuzeichnen der ListBox verhindern
ListBox1.BeginUpdate()
 
' ...
 
' Neuzeichnen wieder einschalten
ListBox1.EndUpdate()