DirectX9 AudioPlayback Wiedergabe von wav, mp3, ogg und co. mit Hilfe von DirectX9 AudioPlayback.
Autor:   Jan Schwien	Bewertung:     [ Jetzt bewerten ]	Views:  12.188
ohne Homepage	System:  Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 16 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 4.5 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Es gibt natürlich noch andere Möglichkeiten Musik mit DirectX9 abzuspielen, aber das hier ist die leichteste und effektivste Variante, wenn es um längere Musik geht bzw. um besondere Datentypen wie z.B. Mp3, wma, ogg.

Fügen Sie Ihrem Projekt zunächst den Verweis "Microsoft.DirectX.AudioVideoPlayback" hinzu.

Erstellen Sie ein neues Klassenmodul mit folgendem Code:

Imports Microsoft.DirectX
Public Class AudioPlayback
  ' Musik ist zu Ende Event
  Public Event AudioEnd(ByVal sender As Object, ByVal e As EventArgs)
 
  ' DirectX9 Audio
  Public WithEvents m_Audio As AudioVideoPlayback.Audio = Nothing
 
  ' Variable : Läuft die Musik noch ?
  Private m_AudioPlaying As Boolean = False

  ''' <summary>
  ''' Lädt die angegebene Audio-Datei
  ''' </summary>
  ''' <param name="Filename">Dateiname der Audio-Datei</param>
  Public Sub Load(ByVal Filename As String)
    m_Audio = New AudioVideoPlayback.Audio(Filename)
  End Sub

  ''' <summary>
  ''' Spielt die Audio-Datei ab
  ''' </summary>
  Public Sub Play()
    Try
      m_Audio.Play()
      m_AudioPlaying = True
    Catch
      m_AudioPlaying = False
    End Try
  End Sub

  ''' <summary>
  ''' Abspielvorgang stoppen
  ''' </summary>
  Public Sub [Stop]()
    m_Audio.Stop()
    m_AudioPlaying = False
  End Sub

  ''' <summary>
  ''' Pause-Funktion für den Abspielvorgang
  ''' </summary>
  Public Sub Pause()
    m_Audio.Pause()
  End Sub

  ' Gibt die Ressourcen frei
  Private Sub Dispose()
    m_Audio.Dispose()
  End Sub

  ''' <summary>
  ''' Beendet die Wiedergabe und gibt die Ressourcen frei
  ''' </summary>
  Public Sub Beenden()
    [Stop]()
    Dispose()
  End Sub

  ''' <summary>
  ''' Legt die Lautstärke fest oder gibt diese zurück
  ''' </summary>
  Public Property Volume() As Integer
    Get
      Return m_Audio.Volume
    End Get
    Set(ByVal value As Integer)
      m_Audio.Volume = value
    End Set
  End Property

  ''' <summary>
  ''' Gibt zurück, ob aktuell ein Abspielvorgang läuft
  ''' </summary>
  Public ReadOnly Property IsPlaying() As Boolean
    Get
      Return m_AudioPlaying
    End Get
  End Property

  ' Löst ein Event aus, wenn der Abspielvorgang beendet ist
  Private Sub Ending(ByVal sender As Object, _
    ByVal e As EventArgs) Handles m_Audio.Ending
 
    m_AudioPlaying = False
 
    ' Event auslösen
    RaiseEvent AudioEnd(sender, e)
  End Sub

End Class

Anwendungsbeispiel:

' Verweis auf unsere AudioPlayback-Klasse
Dim WithEvents Playback As New AudioPlayback

' MP3 abspielen
Playback.Load("d:\temp\MyAudio.mp3")

' Wiedergabe stoppen
Playback.Stop()

' Benachrichtung, wenn Abspielvorgang beendet ist
Private Sub Playback_AudioEnd(ByVal sender As Object, _
  ByVal e As System.EventArgs) Handles Playback.AudioEnd
 
  ' Abspielvorgang beenden
  MsgBox "Wiedergabe beendet!"
End Sub