vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Top-Preis! AP-Access-Tools-CD Volume 1  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2018
 
zurück
Rubrik: Controls · DataGrid & DataGridView   |   VB-Versionen: VB201009.08.11
DataGridView- individuelle Hintergrundgestaltung für ColumnHeader

Eine Funktion, die eine Möglichkeit für das individuelle Gestalten des Hintergrundes der ColumnHeader-Zellen im DataGridView-Control realisiert.

Autor:   Dietrich HerrmannBewertung:     [ Jetzt bewerten ]Views:  10.498 
ohne HomepageSystem:  Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Wer den Hintergrund der ColumnHeader-Zellen eines DatagridView ein wenig individueller gestalten möchte, kann diese Funktion als eine Möglichkeit dafür benutzen.

Die Grundidee ist die Darstellung eines plastischen ('buttonartigen') Hintergrund zu zeigen.
Hierzu benötigt man zunächst eine Definition für die Farbverläufe:

Imports Imports System.Drawing.Drawing2D
...
' Definieren der Farben für die ColumnHeaders der DatagridViews
Public colorBlendDGV As New ColorBlend

Und bspw. dann konkret:

Private Sub Form1_Load(ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles MyBase.Load
 
  ' ColorBlend für ColumnHeaders der DatagridViews festlegen
  With colorBlendDGV
    .Colors = New Color() _
     {Color.WhiteSmoke, Color.LightBlue, Color.LightBlue, Color.Gray}
    .Positions = New Single() {0.0, 0.22, 0.78, 1.0}
  End With
End Sub
''' <summary>
''' Gradient als Hintergrund für ColumnHeaders
''' </summary>
''' <param name="e">DataGridViewCellPaintingEventArgs</param>
''' <param name="colorBlend">Feld für die Gradientfarben</param>
''' <param name="angle">der Winkel für Gradient (90: horizontal)</param>
''' <param name="colMin">die Beginn-Spalte (inkl. RowHeader oder nicht)</param>
''' <param name="borderColor">die Farbe des Randes</param>
''' <param name="innerPadding">inneres Padding für den Text</param>
''' <remarks >im Cellpaint-Ereignis des DatagridView anwenden!</remarks>
Public Sub ColHeadersBG(ByVal e As DataGridViewCellPaintingEventArgs, _
  ByVal colorBlend As ColorBlend, _
  Optional ByVal angle As Single = 90, _
  Optional ByVal colMin As Short = 0, _
  Optional ByVal borderColor As Color = Nothing, _
  Optional ByVal innerPadding As Short = 2)
 
  With e
    ' nur für Header-Zeile ausführen
    If .RowIndex >= 0 OrElse .ColumnIndex < colMin Then Exit Sub
 
    ' Rechteck der Zelle
    Dim rect As New Rectangle(.CellBounds.Left, .CellBounds.Top, .CellBounds.Width, .CellBounds.Height)
 
    ' Rechteck für den Text (mit etwas Padding)
    Dim rectI As New Rectangle(.CellBounds.Left + innerPadding, .CellBounds.Top + innerPadding, _
       .CellBounds.Width - innerPadding * 2, .CellBounds.Height - innerPadding * 2)
 
    Dim cellBrush As New LinearGradientBrush(rect, Color.Red, Color.Blue, angle)
 
    cellBrush.GammaCorrection = True
    cellBrush.InterpolationColors = colorBlend  ' die Hintergrund-Farben definieren 
 
    .Graphics.FillRectangle(cellBrush, .CellBounds)
 
    ' Textformat gemäß Definition festlegen
    Dim sf As New StringFormat
    sf = ConvCellAlignToStringformat(.CellStyle)
 
    ' Text der Zelle zeichnen
    Dim txtBrush As New SolidBrush(.CellStyle.ForeColor)
    If Not IsNothing(.Value) Then
      .Graphics.DrawString(.Value, .CellStyle.Font, txtBrush, rectI, sf)
    End If
 
    ' Rand der Zelle zeichnen
    Dim borderPen As New Pen(borderColor)
    If Not IsNothing(borderColor) Then
      Dim recBorder As New Rectangle(.CellBounds.X - 1, .CellBounds.Y, _
        .CellBounds.Width, .CellBounds.Height - 1)
      .Graphics.DrawRectangle(borderPen, recBorder)
    End If
    .Handled = True
 
    cellBrush.Dispose()
    txtBrush.Dispose()
    borderPen.Dispose()
  End With
End Sub
''' <summary>
''' 	Überführen eines DGVCellAlignments in ein System.Drawing.StringFormat
''' </summary>
''' <param name="theCellStyle">ein DatagridView-Zellstyle</param>
''' <returns>ein dem Cell-Alignment entsprechendes Stringformat</returns>
Private Function ConvCellAlignToStringformat( _
  ByVal theCellStyle As DataGridViewCellStyle) As StringFormat
 
  Dim strFormat As New StringFormat
  With strFormat
    Select Case theCellStyle.Alignment
      Case DataGridViewContentAlignment.NotSet
 
      Case DataGridViewContentAlignment.BottomCenter
        .Alignment = StringAlignment.Center
        .LineAlignment = StringAlignment.Far
      Case DataGridViewContentAlignment.BottomLeft
        .Alignment = StringAlignment.Near
        .LineAlignment = StringAlignment.Far
      Case DataGridViewContentAlignment.BottomRight
        .Alignment = StringAlignment.Far
        .LineAlignment = StringAlignment.Far
      Case DataGridViewContentAlignment.MiddleCenter
        .Alignment = StringAlignment.Center
        .LineAlignment = StringAlignment.Center
      Case DataGridViewContentAlignment.MiddleLeft
        .Alignment = StringAlignment.Near
        .LineAlignment = StringAlignment.Center
      Case DataGridViewContentAlignment.MiddleRight
        .Alignment = StringAlignment.Far
        .LineAlignment = StringAlignment.Center
      Case DataGridViewContentAlignment.TopCenter
        .Alignment = StringAlignment.Center
        .LineAlignment = StringAlignment.Near
      Case DataGridViewContentAlignment.TopLeft
        .Alignment = StringAlignment.Near
        .LineAlignment = StringAlignment.Near
      Case DataGridViewContentAlignment.TopRight
        .Alignment = StringAlignment.Far
        .LineAlignment = StringAlignment.Near
    End Select
 
    Select Case theCellStyle.WrapMode
      Case True
        .FormatFlags = StringFormatFlags.FitBlackBox
      Case Else
        .FormatFlags = StringFormatFlags.NoWrap
    End Select
  End With
  Return strFormat
End Function

Dann die Funktion im CellPaint-Ereignis des DGV anwenden:

Private Sub DataGridView1_CellPainting(ByVal sender As Object, _
  ByVal e As System.Windows.Forms.DataGridViewCellPaintingEventArgs) _
  Handles DataGridView1.CellPainting
 
  ColHeadersBG(e, colorBlendDGV, , -1, DataGridView1.GridColor)
End Sub

Dieser Tipp wurde bereits 10.498 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2018 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel