vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevAniGif - als kostenlose Vollversion auf unserer vb@rchiv CD Vol.5  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Controls · ComboBox   |   VB-Versionen: VB4, VB5, VB616.05.02
Checkbox in der Combobox

Dieses Beispiel zeigt, wie sich eine CheckBox innerhalb einer ComboBox anzeigen lässt.

Autor:   Marcus JacobBewertung:     [ Jetzt bewerten ]Views:  17.454 
www.jacob-software-development.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Manchmal ist es notwendig, das man die Aktivierung einer Combobox und damit die getroffenen Auswahl visuell darstellen kann. Was bietet sich hier eher an, als die Combobox mit einer Checkbox zu versehen. Hiermit kann man die Combobox komfortabel aktivieren oder deaktivieren.

Es soll aber nun die Checkbox in die Combobox integriert werden!

Wie so oft, hilft uns für die Realisierung wieder einmal das Windows API aus der Klemme (oder auf die Sprünge)

Der Reihe nach...

  1. Ziehen Sie auf die Form zunächst eine Checkbox und eine Combobox.
  2. Die Checkbox verkleinern Sie soweit, dass nur noch das Kästchen sichbar ist (195x195 Twips)
  3. Setzen Sie die Value-Eigenschaft der CheckBox auf "1-Aktiviert"
  4. Anschließend kopieren Sie u.a. Code in den Code-Teil der Form

Option Explicit
 
' API-Funktionen
Private Declare Function FindWindowEx Lib "user32" _
  Alias "FindWindowExA" ( _
  ByVal hwndParent As Long, _
  ByVal hwndChildAfter As Long, _
  ByVal lpszClass As String, _
  ByVal lpszWindow As String) As Long
 
Private Declare Function SendMessageLong Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Long) As Long
 
' API-Konstanten
Private Const EC_LEFTMARGIN = &H1
Private Const EC_RIGHTMARGIN = &H2
Private Const EC_USEFONTINFO = &HFFFF&
Private Const EM_SETMARGINS = &HD3&
Private Const EM_GETMARGINS = &HD4&
Private Sub Form_Load()
  Dim i As Long
 
  ' Checkbox zur Combobox hinzufügen
  Call ChkToCbo(Check1, Combo1)
 
  ' Füllen der ComboBox mit Text
  For i = 1 To 20
    Combo1.AddItem "Eintrag" & i
  Next i
End Sub
Private Sub Check1_Click()
  ' Aktivierung der Combobox mittels Checkbox
  If Check1 = vbChecked Then
    Combo1.Enabled = True
  Else
    Combo1.Enabled = False
  End If
End Sub
' Hinzufügen der Checkbox zur ComboBox
Private Sub ChkToCbo(ByRef CheckboxName As CheckBox, _
  ByRef ComboName As ComboBox)
 
  Dim cbohWnd As Long
  Dim MarginLeft As Long
  Dim mvLeft As Long
  Dim mvTop As Long
  Dim mvWidth As Long
  Dim mvHeight As Long
 
  ' Suchen des Fensterhandle der Combobox
  cbohWnd = FindWindowEx(ComboName.hwnd, 0, _
    "EDIT", vbNullString)
 
  ' Parameter zum Verschieben setzen
  mvLeft = ComboName.Left + 3 * Screen.TwipsPerPixelX
  mvTop = ComboName.Top + 2 * Screen.TwipsPerPixelY
  mvWidth = CheckboxName.Width
  mvHeight = ComboName.Height - 4 * Screen.TwipsPerPixelY
 
  ' Platzieren der Checkbox
  If (cbohWnd <> 0) Then
    ' Verschieben der Checkbox
    CheckboxName.Move mvLeft, mvTop, mvWidth, mvHeight
    CheckboxName.BackColor = ComboName.BackColor
    CheckboxName.ZOrder
 
    ' Ausrichten der Texteinträge der Combobox
    MarginLeft = CheckboxName.Width \ Screen.TwipsPerPixelX + 2
    SendMessageLong cbohWnd, EM_SETMARGINS, _
      EC_LEFTMARGIN, MarginLeft
  End If
End Sub

Fertig ist die Checkbox in der Combobox!

Nach dem Start Ihrer Anwendung befindet sich die Checkbox im linken Teil der Combobox und der Text der Combobox ist nach rechts verschoben. Nun läßt sich die Combobox visuell anspruchsvoll mit Hilfe der Checkbox aktivieren oder deaktivieren.

Viel Spaß damit.
 

Dieser Tipp wurde bereits 17.454 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel