vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
SEPA-Dateien erstellen inkl. IBAN-, BLZ-/Kontonummernprüfung  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Drucker   |   VB-Versionen: VB4, VB5, VB603.02.03
MSChart-Diagramm ausdrucken

Dieser Tipp verrät, wie sich ein Diagramm - erstellt mit dem MSChart-Control - sehr leicht ausdrucken lässt.

Autor:   Dietmar G. BayerBewertung:     [ Jetzt bewerten ]Views:  29.642 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Nachfolgender Tipp zeigt, wie sich ein Diagramm, das mit dem MSChart-Control erstellt wurde, sehr leicht ausdrucken lässt. Hierbei wird das Seitenverhältnis der Grafik (Höhe : Breite) autom. berücksichtigt und das Diagramm dann entweder im Hoch- oder Querformat ausgedruckt.

Der Trick besteht darin, das Diagramm zunächst als Bild in die Zwischenablage zu kopieren, dieses dann in eine unsichtbare ImageBox einzufügen, um letztendlich das Bild unter Berücksichtigung der Seitenverhältnisse an das Printer-Objekt zu schicken.

Starten Sie ein neues Projekt, aktivieren über Projekt - Komponenten das MSChart-Control und platzieren dieses auf die Form. Weiterhin benötigen wir noch ein ImageBox-Objekt (Image1), dessen Eigenschaft Visible auf False gesetzt wird und ein CommandButton (Command1), über den der Ausdruck gestartet werden soll.

Private Sub Command1_Click()
  ' Zunächst den das Diagramm in die Zwischenablage
  ' kopieren
  MSChart1.EditCopy
 
  ' Jetzt die Daten der Zwischenablage in das
  ' Image-Objekt einfügen
  Image1.Picture = Clipboard.GetData()
 
  ' Und abschließend das Bild bestmöglichst
  ' ausdrucken (entweder im Hoch- oder im Querformat)
  PrintPictureToFitPage Printer, Image1.Picture
End Sub
Sub PrintPictureToFitPage(Prn As Printer, pic As Picture)
  Dim PicRatio As Double
  Dim PrnWidth As Double
  Dim PrnHeight As Double
  Dim PrnRatio As Double
  Dim PrnPicWidth As Double
  Dim PrnPicHeight As Double
 
  Const vbHiMetric As Integer = 8
 
  With Prn
    ' Entscheidet, ob hochkant oder querkant und setzt
    ' die Orientation
    If pic.Height >= pic.Width Then
      .Orientation = vbPRORPortrait
    Else
      .Orientation = vbPRORLandscape
    End If
 
    ' Verhältnisbererechnng (ratio)
    PicRatio = pic.Width / pic.Height
 
    ' Berechnung des Druck-Bereichs
    PrnWidth = .ScaleX(.ScaleWidth, .ScaleMode, vbHiMetric)
    PrnHeight = .ScaleY(.ScaleHeight, .ScaleMode, vbHiMetric)
 
    ' Und Das Druck-Bereichsverhältniss
    PrnRatio = PrnWidth / PrnHeight
 
    ' Skalieren
    If PicRatio >= PrnRatio Then
      ' Auf maximale Papierbreite skalieren
      PrnPicWidth = .ScaleX(PrnWidth, vbHiMetric, .ScaleMode)
      PrnPicHeight = .ScaleY(PrnWidth / PicRatio, vbHiMetric, _
        Prn.ScaleMode)
    Else
      ' Scale picture to fit full height of printable area
      ' Auf maximale Papierhöhe skalieren
      PrnPicHeight = .ScaleY(PrnHeight, vbHiMetric, .ScaleMode)
      PrnPicWidth = .ScaleX(PrnHeight * PicRatio, vbHiMetric, _
        .ScaleMode)
    End If
 
    ' Drucken
    .PaintPicture pic, 0, 0, PrnPicWidth, PrnPicHeight
 
    ' Druckvorgang beenden
    .EndDoc
  End With
End Sub

Dieser Tipp wurde bereits 29.642 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel