vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevDataGrid - Gönnen Sie Ihrem SQL-Kommando diesen krönenden Abschluß!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2018
 
zurück
Rubrik: Controls · ListView   |   VB-Versionen: VB4, VB5, VB614.02.03
ListView ohne horizontalen Scrollbalken

Mit einer einfachen Berechnung lassen sich die Spaltenbreiten so aufteilen, dass kein horizontaler Scrollbalken angezeigt wird.

Autor:   Dietmar G. BayerBewertung:     [ Jetzt bewerten ]Views:  16.245 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Möchte man verhindern, dass im ListView autom. ein horizontaler Scrollbalken angezeigt wird, braucht man bekanntlich nur dafür zu sorgen, dass man die einzelnen Spalten nicht zu breit festlegt. Möchte man aber auch, dass immer die maximale zur Verfügung stehende Breite genutzt wird, kann das sehr schnell zu einem Geduldsspiel werden: Spaltenbreite ändern - Projekt ausführen - Schauen, ob's passt. Manchmal hat man Glück und es passt (fast) auf Anhieb.

Zu beachten ist dann zusätzlich noch der vertikale Srollbalken

Allem in allem viel zu viel "Testerei", viel zu viel Zeit, die man doch eigentlich effektiver nutzen könnte. Anstelle zwanzig mal die Spaltenbreiten zu ändern, könnte man doch auch eine kleine Prozedur schreiben, die das für einen erledigt

Gehen wir einmal davon aus, dass es Spalten mit fester Breite gibt und eine Spalte, die dann einfach den restlichen Bereich ausfüllen soll.

Beispiel:
Es wird ein ListView mit 5 Spalten benötigt: ArtikelNr, Bezeichnung, Mengeneinheit, BestNr und Preis. Die Spalte ArtikelNr soll 1440 Twips breit sein, Mengeneinheit 1000, BestNr 1440 und Preis 1200. Den Rest nehmen wir für die Bezeichnungspalte.

Jetzt wäre es doch schön, wenn die Spalte "Bezeichnung" autom. angepasst wird. Und genau das erledigt die Prozedur lvwSetMaxWidth. Erwartet werden zwei Parameter: Das ListView-Objekt, sowie der Index der Spalte, deren Breite berechnet werden soll. Zudem lässt sich optional festlegen, ob eine vertikale ScrollBar berücksichtigt werden soll oder nicht. Da die Breite der vertikalen Scrollbar von den Systemeinstellungen bzw. der Auflösung abhängt, lässt sich hier kein pauschaler Wert annehmen. Aber zum Glück gibt es ja noch das Windows API

Option Explicit
 
' Benötigte API-Deklarationen
Private Declare Function GetSystemMetrics Lib "user32.dll" ( _
  ByVal nIndex As Long) As Long
 
Private Const SM_CXVSCROLL = 2
Private Sub Form_Load()
  ' ListView-Spalten festlegen
  With ListView1.ColumnHeaders
    .Add , , "Artikel", 1440
    .Add , , "Bezeichnung"
    .Add , , "ME", 1000
    .Add , , "BestNr", 1440
    .Add , , "Preis", 1200, lvwColumnRight
  End With
 
  lvwSetMaxWidth ListView1, 2
End Sub
Private Sub lvwSetMaxWidth(oListView As ListView, _
  ByVal nColumn As Integer, _
  Optional ByVal bScrollBar As Boolean = True)
 
  ' Breite des vertikalen Scrollbalken
  Dim nVScrollWidth As Long
  If bScrollBar Then
    nVScrollWidth = GetSystemMetrics(SM_CXVSCROLL) * _
      Screen.TwipsPerPixelX
  End If
 
  ' max. zur Verfügung stehende Breite für Spalte
  ' "nColumn" berechnen
  Dim nWidth As Long
  Dim nColWidth As Long
  Dim oColumn As ColumnHeader
 
  With oListView
    For Each oColumn In .ColumnHeaders
      If oColumn.Index <> nColumn Then
        nWidth = nWidth + oColumn.Width
      End If
    Next
 
    nColWidth = .Width - nWidth - nVScrollWidth - 60
 
    ' Spaltenbreite für "nColumn" anpassen
    If nColWidth > 0 Then
      .ColumnHeaders(nColumn).Width = nColWidth
    Else
      .ColumnHeaders(nColumn).Width = 0
    End If
  End With
End Sub

Dieser Tipp wurde bereits 16.245 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2018 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel