vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Erstellen von dynamischen Kontextmen?s - wann immer Sie sie brauchen!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Controls · ListBox   |   VB-Versionen: VB4, VB5, VB603.12.03
Rechtsklick in der Standard-ListBox erkennen

Dieser Tipp zeigt, wie sich in der Standard-ListBox bei rechtem Mausklick der Eintrag ermitteln lässt, auf den der Klick erfolgte.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  13.373 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Beim Verwenden der Standard-ListBox von VB wird beim Klick auf einen Eintrag dieser autom. selektiert. Aber nur, wenn man mit der linken Maustaste auf den Eintrag klickt. Bei einem Rechtsklick tut sich absolut gar nichts

Oftmals braucht man aber gerade die rechte Maustate, um z.B. ein PopUp-Menü anzuzeigen. Hierbei sollte der Eintrag dann aber auch selektiert werden!

Wie das geht, das zeigen wir Ihnen im nachfolgenden Code.

Erstellen Sie ein neues Projekt und platzieren auf die Form eine Standard-ListBox namens List1. Fügen Sie nachfolgenden Code in das Codefenster der Form1 ein:

Option Explicit
 
' Benötigte API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Long) As Long
 
Private Const LB_GETTOPINDEX = &H18E
Private Const LB_GETITEMHEIGHT = &H1A1
Private Sub Form_Load()
  Dim i As Integer
 
  ' ein paar Testeinträge
  For i = 1 To 5
    List1.AddItem "Eintrag " & CStr(i)
  Next i
End Sub
' Bei Rechtsklick Eintrag selektieren
Private Sub List1_MouseDown(Button As Integer, Shift As Integer, _
  X As Single, Y As Single)
 
  Dim nTopIndex As Long
  Dim nItemHeight As Long
  Dim i As Long
  Dim nIndex As Long
  Dim nCount As Long
 
  If Button = vbRightButton Then
    ' nur bei Rechtsklick
    With List1
      ' Ermitteln des ersten Index der Listbox
      nTopIndex = SendMessage(.hwnd, LB_GETTOPINDEX, 0, 0)
 
      ' Ermitteln der Item-Zeichenhöhe
      nItemHeight = SendMessage(.hwnd, _
        LB_GETITEMHEIGHT, 0, 0) * Screen.TwipsPerPixelY
 
      ' Anzahl sichtbarer Einträge
      nCount = .Height / nItemHeight
      If .Height Mod nItemHeight <> 0 Then nCount = nCount + 1
 
      ' Ermitteln des Index, über dem der Mauspfeil steht
      nIndex = nTopIndex - 1
      For i = 0 To List1.Height Step nItemHeight
        If i > Y Then Exit For
        nIndex = nIndex + 1
      Next
 
      If nIndex >= 0 And nIndex < .ListCount Then
        ' Eintrag selektieren
        .ListIndex = nIndex
 
        ' Hier könnte man jetzt z.B. ein PopUp-Menü aufrufen
        ' PopUpMenu MeinPopUp
      End If
    End With
  End If
End Sub

Dieser Tipp wurde bereits 13.373 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel