vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
SEPA-Dateien erstellen inkl. IBAN-, BLZ-/Kontonummernprüfung  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Grafik und Font · Grafische Effekte   |   VB-Versionen: VB5, VB622.12.03
3D Label (Klasse)

Erstellen und Anzeigen von 3D-Texten mit den VB Bordmitteln...

Autor:   Roland WutzkeBewertung:     [ Jetzt bewerten ]Views:  21.501 
www.vb-power.netSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Sie haben Ihre Anwendung soweit fertig! Was fehlt noch? Der letzte Feinschliff wie z.B. ein Info- oder Begrüßungsfenster. Also noch schnell ein Dialog hinzugefügt, eine PictureBox mit dem Logo drauf und etwas Text mit dem Label-Control dabei - fertig! Doch der Text wirk ein wenig langweilig. Etwas Pepp muss her.

Die nachfolgende Klasse demonstriert Ihnen, wie Sie mit dem VB Label ein 3D Label auf der Form platzieren können. Alles was Sie dazu benötigen, sind zwei Label auf der Form. Ein drittes Label kann optional übergeben werden. Den Rest übernimmt die Klasse für Sie. Die Klasse verfügt über folgende Eigenschaften:

  • LabelForeColor (Default: vb3DHighlight)
  • LabelBackColor (Default: vb3DDKShadow)
  • LabelMidColor (Default: vb3Dshadow)
  • TopGap (Schattenversatz Oben, Default: 30 Twips)
  • LeftGap (Schattenversatz Links, Default: 30 Twips)
  • ShadowPos (Schattenposition, Enum ShadowFrom)

Die Aufzählung ShadowFrom stellt Ihnen acht verschiedene Schattenpositionen zur Verfügung:

  • LinksOben
  • MitteOben
  • RechtsOben
  • RechtsMitte
  • LinksMitte
  • LinksUnten
  • MitteUnten
  • RechtsUnten

Die Default-Werte für die LabelFore-, LabelMid- und LabelBackColor-Eigenschaften entsprechen den System 3D-Farben des jeweiligen Zielsystems, so dass der Anwender seine gewohnten Farben erhält. Sie können jedoch die Farben an Ihre Anwendung anpassen.

Die Eigenschaften TopGap und LeftGap bestimmen den Abstand des Schattens in Twips. Die Default-Werte sind jeweils 30 Twips. Mit der Methode "Init" werden der Klasse die beiden benötigten Labels übergeben. Das MidLabel kann optional übergeben werden. Anschließend werden die Labels in Form gebracht und der 3D-Effekt gezeichnet.

Anlegen der Klasse:
Erstellen Sie ein neues Projekt und fügen Sie ein leeres Klassenmodul ein. Benennen Sie das Klassenmodul "clsLabel3D". Kopieren Sie den nachfolgenden Code in das Klassenmodul.

' ***********************************************************
' *
' *   3D Label (Klasse)
' *
' *   Diese Klasse zeichnet ein 3D Label auf einer Form.
' *   Benötigt werden zwei Label-Controls auf der
' *   aufrufenden Form. Die Labels werden der Prozedure
' *   "Init" übergeben. Optional kann ein drittes Label
' *   als MidLabel übergeben werden.
' *
' *   Eigenschaften:
' *     - LabelForeColor (Default: vb3DHighlight)
' *     - LabelBackColor (Default: vb3DDKShadow)
' *     - Optional MidBackColor (Default: vb3DShadow)
' *     - TopGap (Schattenversatz Oben, Default: 30 Twips)
' *     - LeftGap (Schattenversatz Links, Default: 30 Twips)
' *     - ShadowPos (Schattenposition, Enum ShadowFrom)
' *
' *   Dezember 2003, VB-Power.net & Roland Wutzke
' *   http://www.vb-power.net
' *   mailto:snoopy@vb-power.net
' *
' ***********************************************************
 
Option Explicit
 
' Eigenschaften der Klasse
Public LabelForeColor As OLE_COLOR
Public LabelBackColor As OLE_COLOR
Public LabelMidColor As OLE_COLOR
Public TopGap As Long
Public LeftGap As Long
Public ShadowPos As ShadowFrom
 
' Position des BackLabel
Public Enum ShadowFrom
  LinksOben
  MitteOben
  RechtsOben
  RechtsMitte
  LinksMitte
  LinksUnten
  MitteUnten
  RechtsUnten
End Enum
Private Sub Class_Initialize()
  ' Eigenschaften vorbesetzen
  LabelForeColor = vb3DHighlight
  LabelBackColor = vb3DDKShadow
  LabelMidColor = vb3DShadow
  TopGap = 30
  LeftGap = 30
  ShadowPos = LinksMitte
End Sub
Public Sub Init(ForeLabel As Label, BackLabel As Label, _
  Optional MidLabel As Label)
 
  Dim ForeTop As Long
  Dim ForeLeft As Long
  Dim MTopGap As Long
  Dim MLeftGap As Long
 
  ' Top und Left in Variable retten
  ForeTop = ForeLabel.Top
  ForeLeft = ForeLabel.Left
  MTopGap = TopGap \ 2
  MLeftGap = LeftGap \ 2
 
  ' Farben setzen
  ForeLabel.ForeColor = LabelForeColor
  BackLabel.ForeColor = LabelBackColor
 
  ' BackStyle setzen
  ForeLabel.BackStyle = vbTransparent
  BackLabel.BackStyle = vbTransparent
 
  ' Schatten positionieren
  With BackLabel
    Select Case ShadowPos
      Case LinksOben
        .Top = ForeTop - TopGap
        .Left = ForeLeft - LeftGap
      Case MitteOben
        .Top = ForeTop - TopGap
        .Left = ForeLeft
      Case RechtsOben
        .Top = ForeTop - TopGap
        .Left = ForeLeft + LeftGap
      Case RechtsMitte
        .Top = ForeTop
        .Left = ForeLeft + LeftGap
      Case LinksMitte
        .Top = ForeTop
        .Left = ForeLeft - LeftGap
      Case LinksUnten
        .Top = ForeTop + TopGap
        .Left = ForeLeft - LeftGap
      Case MitteUnten
        .Top = ForeTop + TopGap
        .Left = ForeLeft
      Case RechtsUnten
        .Top = ForeTop + TopGap
        .Left = ForeLeft + LeftGap
    End Select
  End With
 
  ' MidLabel vorhanden, dann Anzeigen
  If Not MidLabel Is Nothing Then
 
    ' Farbe MidLabel setzen
    MidLabel.ForeColor = LabelMidColor
 
    ' BackStyle setzen
    MidLabel.BackStyle = vbTransparent
 
    ' In den Hintergrund schieben
    MidLabel.ZOrder 1
 
    ' Schatten positionieren
    With MidLabel
      Select Case ShadowPos
        Case LinksOben
          .Top = ForeTop - MTopGap
          .Left = ForeLeft - MLeftGap
        Case MitteOben
          .Top = ForeTop - MTopGap
          .Left = ForeLeft
        Case RechtsOben
          .Top = ForeTop - MTopGap
          .Left = ForeLeft + MLeftGap
        Case RechtsMitte
          .Top = ForeTop
          .Left = ForeLeft + MLeftGap
        Case LinksMitte
          .Top = ForeTop
          .Left = ForeLeft - MLeftGap
        Case LinksUnten
          .Top = ForeTop + MTopGap
          .Left = ForeLeft - MLeftGap
        Case MitteUnten
          .Top = ForeTop + MTopGap
          .Left = ForeLeft
        Case RechtsUnten
          .Top = ForeTop + MTopGap
          .Left = ForeLeft + MLeftGap
      End Select
    End With
  End If
 
  ' Wichtig!!! Label Reihenfolge setzen
  ForeLabel.ZOrder 0
  BackLabel.ZOrder 1
End Sub

Wie wird die Klasse genutzt:
Ein Beispiel: Platzieren Sie ein Standard VB-Label (Label1) auf die Form1 und stellen Sie die Index-Eigenschaft auf 0 ein. Fügen Sie den nachfolgenden Code in das Codefenster der Form ein:

Option Explicit
 
Private L3d As clsLabel3D
 
Private Sub Form_Load()
  Dim x As Long
 
  ' Klasse instanzieren
  Set L3d = New clsLabel3D
 
  ' Label1 initialisieren
  With Label1(0)
    .Caption = "3D Label"
    .FontName = "Times New Roman"
    .FontSize = 36
    .FontBold = True
    .AutoSize = True
  End With
 
  ' Instanz von Label1 erzeugen
  For x = 1 To 2
    Load Label1(x)
    Label1(x).Visible = True
  Next x
 
  ' Klasse initialisieren und Label zeichnen
  With L3d
    .LeftGap = 50
    .TopGap = 50
    .ShadowPos = RechtsOben
    .Init Label1(0), Label1(1), Label1(2)
  End With
End Sub

So, das war´s. Nutzen Sie die Klasse, um ein eigenes ActiveX-Control zu erstellen. Oder bauen Sie diese Klasse einfach in Ihre Projekte ein.
Viel Spaß damit...
 

Dieser Tipp wurde bereits 21.501 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel