Datensatz duplizieren (ADO) Einen beliebigen Datensatz aus einem Recordset duplizieren
Autor:   Roland Wutzke	Bewertung:     [ Jetzt bewerten ]	Views:  25.417
www.vb-power.net	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 26 Bewertung insgesamt: nützlich Durchschnittliche Bewertung: 3.4 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Oftmals kommt es vor, dass man einen bestehenden Datensatz einfach nur duplizieren möchte, z.B. dann wenn Sie in Ihrer Kundenverwaltung einen weiteren Ansprechpartner einer Firma zuordnen müssen.

Mit der nachfolgenden Routine können Sie einen beliebigen Datensatz aus einem Recordset einfach und universell duplizieren.

Fügen Sie den Code in ein Modul ein:

Public Function DuplicateDS(sRST As ADODB.Recordset, _
  ByVal DS As Long) As Boolean
 
  Dim CloneRST As ADODB.Recordset
  Dim Feld As Variant
 
  ' Fehlerbehandlung aktivieren
  ' z.b: falls Recordset geschlossen, etc.
  On Error Goto ErrHandler
 
  ' Prüfen, ob Recordset nur ReadOnly
  If sRST.LockType = adLockReadOnly Then Exit Function
 
  ' Kopie des Recordsets erstellen
  Set CloneRST = sRST.Clone
 
  With CloneRST
    ' Nur, wenn Daten vorhanden
    If .RecordCount > 0 Then
      ' Datensatzzeiger positionieren
     If DS <= .RecordCount Then
       If Not .BOF Then .MoveFirst
       .Move DS - 1
 
        ' Neuer Datensatz erzeugen
        sRST.AddNew
 
        ' Felder aus Clone-Recordset lesen und in 
        ' Original-Recordset speichern
        On Error Resume Next
        For Each Feld In .Fields
          sRST.Fields(Feld.Name).Value = Feld.Value
        Next Feld
        On Error Goto ErrHandler
 
        ' Datensatz speichern
        sRST.Update
 
        ' Duplizieren erfolgreich abgeschlossen
        DuplicateDS = True
      End If
    End If
  End With
 
ErrHandler:
  ' Clone-Recordset schließen
  On Error Resume Next
  If Not CloneRST Is Nothing Then
    CloneRST.Close
    Set CloneRST = Nothing
  End If
  On Error Goto 0 
End Function

Folgendes Beispiel dupliziert den Datensatz Nr. 3 aus dem Recordset "myRecordSet":

If DuplicateDS(myRecordSet, 3) Then
  MsgBox "Datensatz erfolgreich dupliziert", vbInformation
Else
  MsgBox "Datensatz konnte nicht dupliziert werden", vbCritical
End If