vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
TOP-Angebot: 17 bzw. 24 Entwickler-Vollversionen zum unschlagbaren Preis!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Oberfläche · Fenster   |   VB-Versionen: VB4, VB5, VB625.07.05
Hintergrund-Farbverlauf für die MDIForm

Mit ein bisschen API-Nachhilfe lässt sich der triste Hintergrund einer MDIForm in einen schönen Farbverlauf verwandeln.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  12.347 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Ein großer Nachteil von MDI-Projekten ist der, dass der Hintergrund der MDIForm immer im tristen Standard-Grau von Windows dargestellt wird. Heute möchten wir Ihnen eine Möglichkeit aufzeigen, wie man das triste Grau in einen schönen Farbverlauf verwandeln kann. Hierzu fügen wir der MDIForm zur Laufzeit eine PictureBox hinzu, die wir über die gesamte Größe des MDI-Clientbereichs positionieren, um darin dann den Farbverlauf anzuzeigen.

Erstellen Sie ein neues Projekt und fügen diesem eine MDIForm hinzu. Anschließend setzen Sie noch die MDIClient-Eigenschaft der Form1 auf TRUE.

Code im Codeteil der MDIForm:

Option Explicit
 
' benötigte API-Deklarationen
Private Declare Function FindWindowEx Lib "user32" _
  Alias "FindWindowExA" ( _
  ByVal hWnd1 As Long, _
  ByVal hWnd2 As Long, _
  ByVal lpsz1 As String, _
  ByVal lpsz2 As String) As Long
 
Private Declare Function SetParent Lib "user32" ( _
  ByVal hWndChild As Long, _
  ByVal hWndNewParent As Long) As Long
 
Private Declare Function GetClientRect Lib "user32" ( _
  ByVal hwnd As Long, _
  lpRect As RECT) As Long
 
Private Declare Function MoveWindow Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal x As Long, _
  ByVal y As Long, _
  ByVal nWidth As Long, _
  ByVal nHeight As Long, _
  ByVal bRepaint As Long) As Long
 
Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type
 
' Handle des Client-Window
Private hWndClient As Long
 
' temporäre PictureBox für den Farbverlauf
Dim WithEvents MDIPicture As PictureBox
Private Sub MDIForm_Load()
  ' Handle des MDIClient-Window ermitteln
  hWndClient = FindWindowEx(Me.hwnd, 0, "MDIClient", "")
 
  ' temporäre PictureBox für den Farbverlauf
  Set MDIPicture = MDIForm1.Controls.Add("VB.PictureBox", "MDIPicture1")
  MDIPicture.Visible = True
 
  ' PictureBox in das MDIClient-Window setzen
  SetParent MDIPicture.hwnd, hWndClient
 
  ' Child-Form anzeigen
  Form1.Show
End Sub
Private Sub MDIForm_Resize()
  Dim R As RECT
 
  ' Größe und Position des MDIClient-Window ermitteln
  GetClientRect hWndClient, R
 
  ' PictureBox-Größe entsprechend anpassen
  MoveWindow MDIPicture.hwnd, R.Left, R.Top, R.Right, R.Bottom, True
End Sub
Private Sub MDIForm_Unload(Cancel As Integer)
  ' temporäre PictureBox sauber entladen
  Me.Controls.Remove MDIPicture
  Set MDIPicture = Nothing
End Sub
Private Sub MDIPicture_Paint()
  ' Farbverlauf anzeigen
  MakeGradient MDIPicture, vbBlack, vbWhite, 1
End Sub

Die Funktion "MakeGradient" stammt aus dem Tipp Farbverlauf in Fenstern und Objekten. Fügen Sie den entsprechenden Code am besten in ein neues Modul ein.
 

Dieser Tipp wurde bereits 12.347 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel