vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Zippen wie die Profis!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Maus & Tastatur · Maus   |   VB-Versionen: VB5, VB625.10.07
Animierte Mauszeiger verwenden

Standardmäßig kann man in VB keine animierten Mauszeiger anzeigen. Mit einem Trick in die Windows-API Kiste ist das aber dennoch möglich.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  11.442 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Standardmäßig kann man in VB keine animierten Mauszeiger anzeigen. Mit einem Trick in die Windows-API Kiste ist das aber dennoch möglich. Auf diese Weise können Sie beispielsweise Ihren eigenen "Wait"-Cursor benutzen anstelle der Standard-Sanduhr.

Fügen Sie nachfolgenden Code in ein Modul ein:

Option Explicit
 
' Benötigte API-Deklarationen
Private Declare Function LoadCursorFromFile Lib "user32" _
  Alias "LoadCursorFromFileA" ( _
  ByVal lpFileName As String) As Long
 
Private Declare Function SetCursor Lib "user32" ( _
  ByVal hCursor As Long) As Long
 
Private Declare Function SetCapture Lib "user32" ( _
  ByVal hwnd As Long) As Long
 
Private Declare Function ReleaseCapture Lib "user32" () As Long
 
' Window-Handle der Form, in der der animierte
' Cursor angezeigt werden soll
Private hwnd As Long
 
' Mauszeiger - ursprüngliches Handle
Private hCursorOld As Long
 
' Handle des neuen Mauszeigers
Private hCursor As Long
' benutzerdefinierten Mauszeiger laden und anzeigen
Public Function SetMouseCursor(ByVal nWnd As Long, _
  ByVal sFile As String) As Boolean
 
  ' zunächst Mausereignisse eines früheren Aufrufs
  ' freigeben und ursprünglichen Cursor wiederherstellen
  ReleaseMouseCursor
 
  Dim nResult As Long
 
  ' Cursor aus Datei laden
  hCursor = LoadCursorFromFile(sFile)
  If hCursor <> 0 Then
    hwnd = nWnd
    ' Mausereignisse auf die Form umleiten
    SetCapture hwnd
 
    ' neuen Cursor festlegen
    hCursorOld = SetCursor(hCursor)
    SetMouseCursor = True
  End If
End Function
' benutzerdefinierten Mauszeiger zerstören
' und ursprünglichen Cursor wiederherstellen
Public Sub ReleaseMouseCursor()
  If hwnd <> 0 Then
    If hCursor <> 0 And hCursorOld <> hCursor Then
      SetCursor hCursorOld
      ReleaseCapture
    End If
  End If
 
  hwnd = 0
  hCursor = 0
  hCursorOld = 0
End Sub

Soll nun während einer bestimmten (länger dauerenden) Aktion ein eigener "Wait"-Cursor angezeigt werden, verwenden Sie folgenden Aufruf:

Private Sub DoSomething()
  ' eigenen animierten Mauszeiger laden und anzeigen
  SetMouseCursor Me.hWnd, App.Path & "\waitcursor.ani"
 
  ' hier die Aktion (Berechnung) etc.
  ' ...
 
  ' Standard-Mauszeiger wiederherstellen
  ReleaseMouseCursor
End Sub

Dieser Tipp wurde bereits 11.442 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel