Fenster in der Taskbar anzeigen ein/aus Mit diesem Trick lässt sich ein Fenster zur Laufzeit in der Taskbar anzeigen und auch wieder ausblenden.
Autor:   Thomas Bannert	Bewertung:     [ Jetzt bewerten ]	Views:  22.997
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 21 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.9 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Die Form-Eigenschaft ShowInTaskbar kann bekanntlich nur zur Entwurfszeit gesetzt werden. Die Eigenschaft gibt an, ob das Fenster in der Windows-Taskbar angezeigt werden soll oder nicht. Mit der nachfolgenden Prozedur ist es möglich diese Eigenschaft auch zur Laufzeit zu setzen. Somit kann ein Fenster nachträglich in der Taskbar angezeigt bzw. aus der Taskbar entfernt werden.

Entgegen unserem früheren Tipp wird der Fensterstil dieses Mal nicht verändert!

Fügen Sie nachfolgende Code in ein Modul ein:

Option Explicit
 
' alle benötigten Deklarationen
Private Declare Function GetWindowLong Lib "user32" _
  Alias "GetWindowLongA" ( _
  ByVal hwnd As Long, _
  ByVal nIndex As Long) As Long
 
Private Declare Function SetWindowLong Lib "user32" _
  Alias "SetWindowLongA" ( _
  ByVal hwnd As Long, _
  ByVal nIndex As Long, _
  ByVal dwNewLong As Long) As Long
 
Private Declare Function ShowWindow Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal nCmdShow As Long) As Long
 
Private Declare Function GetDesktopWindow Lib "user32" () As Long
 
Private Declare Function LockWindowUpdate Lib "user32" ( _
  ByVal hwndLock As Long) As Long
 
Private Const SW_HIDE = 0
Private Const SW_SHOW = 5
Private Const GWL_EXSTYLE = (-20)
 
Public Const WS_EX_APPWINDOW = &H40000

' Fenster in der Taskbar anzeigen ein/aus
Public Sub FormInTaskbar(lhwnd As Long, _
  ByVal ShowInTaskBar As Boolean)
 
  Dim lStyle As Long
  Dim lResult As Long
 
  ' Flackern verhindern
  LockWindowUpdate GetDesktopWindow
 
  ' Form ausblenden
  lResult = ShowWindow(lhwnd, SW_HIDE)
 
  ' Window Style festlegen
  lStyle = GetWindowLong(lhwnd, GWL_EXSTYLE)
  If ShowInTaskBar = True Then
    lStyle = lStyle Or WS_EX_APPWINDOW
  Else
    lStyle = lStyle And Not WS_EX_APPWINDOW
  End If
 
  ' Neues Window Syle setzen
  SetWindowLong lhwnd, GWL_EXSTYLE, lStyle
 
  ' Form einblenden
  lResult = ShowWindow(lhwnd, SW_SHOW)
 
  LockWindowUpdate 0&
End Sub

Beispiel für den Aufruf aus einer Form heraus:

Private Sub Command1_Click()
  ' In Taskbar anzeigen
  FormInTaskbar Me.hwnd, True
  Command1.Enabled = False
  Command2.Enabled = True
End Sub

Private Sub Command2_Click()
  ' In Taskbar ausblenden
  FormInTaskbar Me.hwnd, False
  Command1.Enabled = True
  Command2.Enabled = False
End Sub