vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v3.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Controls · TextBox & RichTextBox   |   VB-Versionen: VB618.01.08
Textlänge prüfen und mit Punkten modifizieren II

Ersetzt Zeichen die nicht in eine TextBox (MultiLine = False) passen, durch 3 Punkte

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  9.980 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Vor wenigen Tagen haben wir Ihnen einen Tipp vorgestellt, mit dem sich der Text innerhalb einer Textbox so kürzen lässt, dass dieser ggf. mit abschließenden "..." angezeigt wird, wenn dieser nicht vollständig sichtbar in die TextBox passt:  Textlänge prüfen und mit Punkten modifizieren

Nachfolgender Tipp tut genau das Gleiche - berücksichtigt jedoch die eingestellte Schrift der TextBox und verzichtet auf die While..Wend Schleife zur zeichenweise Kürzung des Textes. Außerdem spielt es hier auch keine Rolle, ob die TextBox mit oder ohne "Border" angezeigt wird, da der "Innenbereich" der TextBox autom. über die "GetClientRect"-Funktion ermittelt werden.

Benötigte Controls:

  • eine TextBox (Text1)
  • ein CommandButton (Command1)

    Die 3 Punkte am Ende der Textanzeige werden erst gesetzt, wenn der Text nicht vollständig lesbar in der TextBox angezeigt werden kann.
    Damit der ursprüngliche Text nicht verloren geht, wird dieser dann als ToolTipText angezeigt.

    Option Explicit
     
    ' benötigte API-Deklarationen
    Private Declare Function DrawText Lib "user32" _
      Alias "DrawTextA" ( _
      ByVal hDC As Long, _
      ByVal lpStr As String, _
      ByVal nCount As Long, _
      lpRect As RECT, _
      ByVal wFormat As Long) As Long
     
    Private Declare Function GetClientRect Lib "user32" ( _
      ByVal hwnd As Long, _
      lpRect As RECT) As Long
     
    Private Declare Function GetDesktopWindow Lib "user32" () As Long
     
    Private Declare Function SelectObject Lib "gdi32.dll" ( _
      ByVal hDC As Long, _
      ByVal hObject As Long) As Long
     
    Private Declare Function GetDC Lib "user32" ( _
      ByVal hwnd As Long) As Long
     
    Private Declare Function ReleaseDC Lib "user32" ( _
      ByVal hwnd As Long, _
      ByVal hDC As Long) As Long
     
    Private Declare Function CreateCompatibleDC Lib "gdi32.dll" ( _
      ByVal hDC As Long) As Long
     
    Private Declare Function DeleteDC Lib "gdi32.dll" ( _
      ByVal hDC As Long) As Long
     
    Private Const DT_END_ELLIPSIS = &H8000&
    Private Const DT_MODIFYSTRING = &H10000
    Private Const DT_SINGLELINE = &H20&
    Private Const DT_NOPREFIX = &H800
     
    Private Type RECT
      Left As Long
      Top As Long
      Right As Long
      Bottom As Long
    End Type
    Private Sub Form_Load()
      ' Vorgabe
      Text1.Width = 2745
      Text1.Text = "Das ist ein etwas längerere Text, " & vbCrLf & _
        "der nicht komplett sichtbar angezeigt wird!"
    End Sub
    Private Sub Command1_Click()
      ' Textinhalt prüfen und Anzeige ggf. modifizieren
      SetPoints Text1
    End Sub
    ' Textbox-Inhalt auf Länge prüfen und ggf. mit
    ' "..." abschneiden, wobei dann der Originaltext
    ' als ToolTip angezeigt wird
    Private Sub SetPoints(myTextBox As TextBox)
      Dim R As RECT
      Dim sTemp As String
      Dim hDC As Long
      Dim hTempDC As Long
      Dim hOldFont As Long
      Dim oFont As stdole.IFont
     
      With myTextBox
        ' Textinhalt
        sTemp = myTextBox.Text
        If Len(sTemp) > 0 Then
          ' Innenmaße der TextBox ermitteln
          GetClientRect .hwnd, R
     
          ' Handle für Font-Objekt
          Set oFont = .Font
     
          ' Device-Kontext erstellen und Font zuweisen
          hDC = GetDC(GetDesktopWindow)
          hTempDC = CreateCompatibleDC(hDC)
          hOldFont = SelectObject(hTempDC, oFont.hFont)
     
          ' DrawText-API aufrufen
          ' Die Funktion modifiziert autom. den übergeben String
          DrawText hTempDC, sTemp, -1, R, DT_SINGLELINE Or _
            DT_END_ELLIPSIS Or DT_NOPREFIX Or DT_MODIFYSTRING
     
          ' alte Font wiederherstellen und Device-Kontext freigeben
          Call SelectObject(hTempDC, hOldFont)
          DeleteDC hTempDC
          ReleaseDC GetDesktopWindow, hDC
     
          ' gekürzten Text anzeigen und Originaltext
          ' als ToolTip speichern
          If InStr(sTemp, Chr$(0)) > 0 Then
            sTemp = Split(sTemp, Chr$(0))(0)
          End If
          If .Text <> sTemp Then
            .ToolTipText = .Text
            .Text = sTemp
          Else
            .ToolTipText = ""
          End If
        End If
      End With
    End Sub

  • Dieser Tipp wurde bereits 9.980 mal aufgerufen.

    Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

    Über diesen Tipp im Forum diskutieren
    Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

    Neue Diskussion eröffnen

    nach obenzurück


    Anzeige

    Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
    (einschl. Beispielprojekt!)

    Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
    - nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
    - Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
    Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
     
       

    Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
    Alle Rechte vorbehalten.
    Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

    Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel