lstrlen-Funktion Ermittelt die Anzahl der Zeichen eines Strings bis zum ersten "vbNullChar"-Vorkommen.
Betriebssystem:  Win95, Win98, WinNT 3.1, Win2000, WinME	Views:  5.147

Deklaration:

Declare Function lstrlen Lib "kernel32.dll" _
  Alias "lstrlenA" ( _
  ByVal lpString As Any) As Long

Beschreibung:
Diese Funktion ermittelt die Anzahl der Zeichen eines Strings bis zum ersten "vbNullChar"-Vorkommen.

Parameter:

lpString

String, dessen Länge ermittelt werden soll.

Rückgabewert:
Anzahl der Zeichen bis zum nächsten "vbNullChar" zurück.

Beispiel:

Private Declare Function FindExecutable Lib "shell32.dll" _
  Alias "FindExecutableA"  ( _
  ByVal lpFile As String, _
  ByVal lpDirectory As String, _
  ByVal lpResult As String) As Long 
Private Declare Function lstrlen Lib "kernel32.dll" _
  Alias "lstrlenA" ( _
  ByVal lpString As Any) As Long
 
' FindExecutable Konstanen
Private Const ERROR_FILE_NOT_FOUND = 2&
Private Const ERROR_PATH_NOT_FOUND = 3&
Private Const ERROR_BAD_FORMAT = 11&

Private Sub Command1_Click()
  Dim Retval As Long, Puffer As String
 
  ' Puffergröße festlegen
  Puffer = Space(256)
 
  Retval = FindExecutable("c:\windows\media\tada.wav", "", Puffer)
  Select Case Retval
    Case 0
      Debug.Print "Es ist nicht genügend Speicher vorhanden, " & _
        "um diese Funktion durchzuführen." 
    Case 31
      Debug.Print "Für diese Datei existiert keine verknüpfte Anwendung!"
    Case ERROR_FILE_NOT_FOUND
      Debug.Print "Die angegebene Datei wurde nicht gefunden."
    Case ERROR_PATH_NOT_FOUND
      Debug.Print "Der angegebene Pfad wurde nicht gefunden"
    Case ERROR_BAD_FORMAT
      Debug.Print "Die verknüpfte Anwendung ist ungültig oder keine Win32 Anwendung"
    Case Else
      Debug.Print "Verknüpfte Anwendung: " & Left$(Puffer, lstrlen(Puffer))
      Debug.Print "Verknüpfte Anwendung mit Kommando: " & Left$(Puffer, _
        InStr(1, Puffer, """") - 1)
  End Select
End Sub