Public Class HausConsole
 
		Public Shared Sub Main()
			Try
				Dim myProg As New Program
				myProg.Init()
				myProg.printStatus()
			Catch ex As Exception
				Console.WriteLine(ex.Message + Environment.NewLine + ex.StackTrace)
			End Try
		End Sub
 
	End Class
 
	Public Interface IGeraet
		ReadOnly Property TypName() As String
		ReadOnly Property Name() As String
		ReadOnly Property Status() As String
		Sub Action(ByVal Command As String)
	End Interface
	Public Class Heizung
		Implements IGeraet
 
		Private AktuelleTemperatur As Double = 20.0
		Protected meinName As String
		Public Sub New(ByVal _name As String)
			meinName = _name
		End Sub
 
		Public Sub Action(ByVal Command As String) Implements IGeraet.Action
 
		End Sub
 
		Public ReadOnly Property TypName() As String Implements IGeraet.TypName
			Get
				Return "Heizung"
			End Get
		End Property
		Public ReadOnly Property Name() As String Implements IGeraet.Name
			Get
				Return meinName
			End Get
		End Property
 
		Public ReadOnly Property Status() As String Implements IGeraet.Status
			Get
				Return AktuelleTemperatur.ToString()
			End Get
		End Property
	End Class
	Public Class Fenster
		Implements IGeraet
		Protected meinName As String
		Public Sub New(ByVal _name As String)
			meinName = _name
		End Sub
 
		Public Overridable ReadOnly Property TypName() As String Implements _
  IGeraet.TypName
			Get
				Return "Fenster"
			End Get
		End Property
		Public ReadOnly Property Name() As String Implements IGeraet.Name
			Get
				Return meinName
			End Get
		End Property
		Public Overridable Sub Action(ByVal Command As String) Implements _
  IGeraet.Action
			Select Case Command.ToLower()
				Case "open" : fStatus = FensterStatus.offen
				Case "close" : fStatus = FensterStatus.geschlossen
				Case "kipp" : fStatus = FensterStatus.gekippt
			End Select
			'Hier das Command auswerten
		End Sub
 
		Public Enum FensterStatus
			geschlossen = 0
			offen = 1
			gekippt = 2
		End Enum
 
		Protected fStatus As FensterStatus = FensterStatus.geschlossen
		Public ReadOnly Property Status() As String Implements IGeraet.Status
			Get
				Return fStatus.ToString()
			End Get
		End Property
	End Class
 
	Public Class Tuer
		Inherits Fenster
		Public Sub New(ByVal _name As String)
			MyBase.New(_name)
		End Sub
		Public Overrides ReadOnly Property TypName() As String
			Get
				Return "Tür"
			End Get
		End Property
		Public Overrides Sub Action(ByVal Command As String)
			Select Case Command.ToLower()
				Case "open" : fStatus = FensterStatus.offen
				Case "close" : fStatus = FensterStatus.geschlossen
			End Select
			'Hier das Command auswerten
		End Sub
	End Class
 
 
	Public Class Raum
 
		Private meineGeraete As New GeraeteCollection
		Public ReadOnly Property Geraete() As GeraeteCollection
			Get
				Return meineGeraete
			End Get
		End Property
 
	End Class
 
	Public Class Program
		Public meinRaum As New Raum
 
		Public Sub Init()
			'Hier den Raum mit "Leben" befüllen
			Console.WriteLine("Lege Fenster an")
			meinRaum.Geraete.Add("FensterLinks", New Fenster("Links"))
			meinRaum.Geraete.Add("FensterRechts", New Fenster("Rechts"))
			meinRaum.Geraete.Add("Tür", New Tuer("Eingang"))
 
 
 
			Console.WriteLine("Status FensterLinks:" + meinRaum.Geraete( _
  "FensterLinks").Status)
			Console.WriteLine("Status FensterRechts:" + meinRaum.Geraete( _
"FensterRechts").Status)
 
			Console.WriteLine("Bearbeite Fenster")
 
			meinRaum.Geraete("FensterLinks").Action("Open")
			meinRaum.Geraete("FensterRechts").Action("Kipp")
			meinRaum.Geraete("Tür").Action("Open")
 
 
		End Sub
		Public Sub printStatus()
			For Each geraet As IGeraet In meinRaum.Geraete.Values
				Console.WriteLine("Typ    : " + geraet.TypName)
				Console.WriteLine("Gerät  : " + geraet.Name)
				Console.WriteLine("Status : " + geraet.Status)
			Next
		End Sub
	End Class